[code]
#Include "FiveWin.ch"

REQUEST HB_LANG_PT
REQUEST HB_CODEPAGE_PTISO

#define TEXT_ARRAY { ;
         "Obs: Caso Algum Link Quebre, Avise o Suporte.", ;
         "Cuidado: No Entre em Link Inseguro ou Suspeito.", ;
         "Deixe Sempre, Que o Navegador, Decida.", ;
         "Feche o Internet Explorer Antes de Entrar em Outro Navegador(Ex.: Google Chrome)", ;
         "Se os Botes Sumirem, Feche o Programa. Tente de Novo.", ;
         "Mantenha o Windows e o Anti Vrus Atualizado.  melhor.", ;
         "Antes de Entrar na Internet, Feche Programas da C.E.F.", ;
         "Faa Limpeza dos Caches com o CCleaner.exe - Spams.", ;
         "Faa Limpeza dos Malware com o IObit Malware Fighter - Malware." }

STATIC oWnd

FUNCTION Main()

   LOCAL oIco, oBar, oBmp, oHand, cLinkBBra, cLinkCEF, cLinkItal, cLinkBrad
   LOCAL oServices, cLink_CeF_Cobra, cBBCobranca, oFont, oFnt, cIObit, oElement
   LOCAL nLinha, nColuna

   SET DATE BRITISH
   SET EPOCH TO Year( Date() ) - 80
   SET SOFTSEEK ON
   SET WRAP ON
   SETCANCEL( .F. )
   SET CONFIRM OFF
   SET DELETED ON
   SET ESCAPE ON
   SET EXCLUSIVE OFF
   SET MULTIPLE OFF

   Set( _SET_CODEPAGE, "PTISO" )

   SetBalloon( .T. )
   SkinButtons()     // Botoes Coloridos nas novas versoes

   /*limpia arreglo y llama al colecor de basura de xharbour*/ //-> Lixeira
   hb_gcAll( .F. )

   DEFINE CURSOR oHand HAND
   DEFINE ICON oIco FILE ".\fax.ico"

   DEFINE FONT oFnt  NAME "Ms Sans Serif" SIZE 00,  14 BOLD
   DEFINE FONT oFont NAME "Ms Sans Serif" SIZE 00, -14 BOLD

   DEFINE WINDOW oWnd FROM 1, 1 TO 22, 75                ;
      TITLE "Escolha uma Opo Para Navegar nos Botes Abaixo: " + ;
            " e Escolher o Seu Banco Preferido - Verso: 3.4 20/09/2017"   ;
      COLORS CLR_BLACK, CLR_WHITE ICON oIco

   #ifdef __XHARBOUR__

      nLinha  := 06
      nColuna := 35

      oElement := HB_EnumIndex() // Equivalencia de __EnumIndex do Harbour

      FOR EACH oElement IN TEXT_ARRAY

         @  nLinha, nColuna SAY Padc( oElement, 80 )                         ;
            OF oWnd SIZE 600, 16                                             ;
            COLORS CLR_BLACK, CLR_WHITE FONT oFont TRANSPARENT UPDATE

         nLinha := nLinha + 4.5

      NEXT

   #else  // Harbour

      FOR EACH oElement IN TEXT_ARRAY

         @ oElement:__EnumIndex * 4 + 4, 50 SAY Padc( oElement, 80 )         ;
            OF oWnd SIZE 600, 16                                             ;
            COLORS CLR_BLACK, CLR_WHITE FONT oFont TRANSPARENT UPDATE

      NEXT

   #endif

   // BARRA DOS BOTOES DA JANELA
   DEFINE BUTTONBAR OBAR       ; // 49,60 Fica Muito Legal
          BUTTONSIZE 149, 50   ; // 50,60
          _3DLOOK              ; // Imagem na Tela em 3D
          TOP                  ; // TOP
          OF oWnd 2007         ;
          CURSOR oHand

   // Este modelo e melhor esta em: \samples\testbtb.prg e testgrad.prg
   oBar:bClrGrad := { | lInvert | If( lInvert, ;
       { { 1/3, nRGB( 255, 253, 222 ), nRGB( 255, 231, 151 ) }, ;
         { 2/3, nRGB( 255, 215,  84 ), nRGB( 255, 233, 162 ) }  ;
       }, ;
         { { 1/2, nRGB( 219, 230, 244 ), nRGB( 207-50, 221-25, 255 ) }, ;
         { 1/2, nRGB( 201-50, 217-25, 255 ), nRGB( 231, 242, 255 ) }  ;
       } ) }

   // Cor no Prompt dos Botoes
   // oBar:nClrText = CLR_HBLUE

   oBar:Adjust()

   cLinkBBra := ( "www.bb.com.br" )

   DEFINE BUTTON OF oBar FILENAME ".\LOGO_001.BMP" GROUP TOP     ;
      ACTION( ShellExecute(GetActiveWindow(),"open",'"'+cLinkBBra+'"') ) ;
      TOOLTIP "Dispara para o BB"
   cLinkCEF := ( "www.caixa.gov.br/Paginas/home-caixa.aspx" )

   MENU oServices POPUP 2007

      MENUITEM "Site da C.E.F. &Direto. Quebra?"      ;
         FILENAME ".\prop.bmp"                                     ;
         ACTION( ShellExecute(GetActiveWindow(),"open",'"'+cLinkCEF+'"') )

      cLink_CeF_Cobra := ( "C:\caixa\cobranca\SINCOCli.exe" )
      SEPARATOR
      MENUITEM "Cobrana &C.E.F. Aplicativo Local" ;
         FILENAME ".\HelpInd.bmp"                               ;
         ACTION( ( Chama_Aplicativo( cLink_CeF_Cobra ) ),       ;
                         oWnd:UpDate(), oWnd:Refresh() )

      cBBCobranca := ( "C:\BancoBrasil\BBCobranca\bbcbr.jar" )
      SEPARATOR
      MENUITEM "&BBCobrana Aplicativo Local"      ;
         FILENAME ".\Help.bmp"                                  ;
         ACTION( ( Chama_Aplicativo( cBBCobranca ) ),           ;
                     oWnd:UpDate(), oWnd:Refresh() )

      cIObit := ( "http://www.iobit.com/pt/malware-fighter.php" )

      SEPARATOR
      MENUITEM "&IObit Malware Fighter"                    ;
         FILENAME ".\Help.bmp"                                          ;
         ACTION( ShellExecute(GetActiveWindow(),"open",'"'+cIobit+'"'), ;
                 oWnd:UpDate(), oWnd:Refresh() )

      SEPARATOR
      MENUITEM "&Sair do Programa - Alt+S"    ;
         FILENAME ".\Saida.bmp"               ;
         ACTION( oWnd:End() )

   ENDMENU

   DEFINE BUTTON OF oBar FILENAME ".\LOGO_104.BMP" GROUP TOP     ;
      MENU oServices                                             ;
      ACTION( ShellExecute(GetActiveWindow(),"open",'"'+cLinkCEF+'"') ) ;
      TOOLTIP "Dispara Para a C.E.F. Veja Menu ao Lado"

   cLinkBrad := ( "www.bradesco.com.br/html/classic/index.shtm" )
   DEFINE BUTTON OF oBar FILENAME ".\LOGO_237.BMP" GROUP TOP             ;
      ACTION( ShellExecute(GetActiveWindow(),"open",'"'+cLinkBrad+'"') ) ;
      TOOLTIP "Dispara Para o Brad."

   cLinkItal := ( "www.itau.com.br/" )
   DEFINE BUTTON OF oBar FILENAME ".\LOGO_341.BMP" GROUP TOP             ;
      ACTION( ShellExecute(GetActiveWindow(),"open",'"'+cLinkItal+'"') ) ;
      TOOLTIP "Dispara para o It..."

   DEFINE BUTTON OF oBar FILENAME ".\Exit.bmp"     GROUP TOP ;
      ACTION( oWnd:End() ) TOOLTIP "Sair do Programa"

   DEFINE MESSAGE OF oWnd                  ;
      PROMPT FWVERSION + " " + FWCOPYRIGHT + " - " + "kapiabafwh@gmail.com.br" + ;
                                           + " - " + "(11) 3106-2832 "           ;
      NOINSET CENTERED KEYBOARD DATE CLOCK

   DEFINE BITMAP oBmp FILENAME ".\CONTATO.bmp"

   oWnd:bPainted = { | hDC | BmpTiled( hDC, oWnd, oBmp ) }

   ACTIVATE WINDOW oWnd MAXIMIZED ;
      VALID MsgYesNo( "Deseja Sair do Programa?", "Saida do Programa" )

   oFont:End()
   oFnt:End()

   FreeResources()

   SysRefresh()

   RELEASE All
   Hb_GCAll( .T. )

   CLEAR MEMORY

   PostQuitMessage( 0 )

   __QUIT()

RETURN NIL

FUNCTION BmpTiled( hDC, oWnd, oBmp )

   local nWidth := oWnd:nWidth(), nHeight := oWnd:nHeight()
   local nRow := 0, nCol := 0, n
   local nBmpWidth  := oBmp:nWidth(),  nBmpHeight := oBmp:nHeight()

   if oBmp:hBitmap == 0
      return nil
   endif

   while nRow < nHeight
      nCol = 0
      while nCol < nWidth
         PalBmpDraw( hDC, nRow, nCol, oBmp:hBitmap )
         nCol += nBmpWidth
      end
      nRow += nBmpHeight
   end

   RETURN NIL

FUNCTION ConsultaLink( cLinkExplorer ) // VIA INTERNET EXPLORER

   LOCAL oChildWnd, oActiveX

   MsgWait( "CONECTANDO AO SITE VIA INTERNET EXPLORER", "AGUARDE UM MOMENTO POR FAVOR...         ", 2.5 )

   MeuWinExec( "Start Iexplore.Exe " + cLinkExplorer, 0 )

   RETURN NIL

FUNCTION Chama_Aplicativo( cLinkAplicativo ) // VIA GOOGLE CRHOME ou Nao.

   LOCAL oChildWnd, oActiveX

   MsgWait( "CONECTANDO A UM APLICATIVO LOCAL", "AGUARDE UM MOMENTO POR FAVOR... ", 2.5 )

   MeuWinExec( cLinkAplicativo, 0 )

   RETURN NIL

FUNCTION MeuWinExec( cParametro )

   LOCAL cExecute := GetPvProfString( "" )

   IF IsWinNT() .OR. IsWin2000()
      cExecute := GetEnv( "COMSPEC" ) + " /C "
   ENDIF

RETURN WinExec( cExecute + cParametro, 0 )

// FIM DO PROGRAMA - By Joao Santos - kapiabafwh@gmail.com
[/code]
