fastreport com sql

[andrelucass]

Boa tarde a todos

Estou migrando um sistema em dbf para postgresql e todos os relatorios então em fastreport com dbf esta tudo ok, gostaria de saber se alguem usa o fastreport com algum banco sql

Atenciosamente
André Lucas Souza

[Paredes01]

Hola, lo hago de esta forma
Anexo resultado

Código: Selecionar todos

#Include "SQLRDD.CH"
Procedure REPFACT()
        Local np , nCol, nError, nPos

        BXX(11,10,16,35,,3,8,cCAJA1)
        @ 11,14 SAY "Reporte de Ventas" COLOR COLOR4

        oFr:=frReportManager():New()
        DO WHILE .T.

           @ 13,12 SAY "DESDE   #             "
           @ 14,12 SAY "HASTA   #             "

           dFECINI  = DATE()
           dFECFIN  = DATE()

           @ 13,22 GET dFECINI PICT "@D" VALID DTOC(dFECINI) != "  /  /  "
           READ
           IF LASTKEY() = 27
              EXIT
           ENDIF

           @ 14,22 GET dFECFIN PICT "@D" VALID dFECFIN >= dFECINI
           READ
           IF LASTKEY() = 27
              LOOP
           ENDIF



           cSQL := "SELECT F.FOLIO AS FACTURA, F.FECHA, ISNULL(F.VTAEXE,0.00) AS EXENTAS, ISNULL(F.VTAGRA,0.00) AS GRAVADAS, ISNULL(F.IVA,0.00) AS IVAS, ( ISNULL(F.VTAEXE,0.00) + ISNULL(F.VTAGRA,0.00) + ISNULL(F.IVA,0.00) ) AS TOTALES, STA "
           cSQL += "FROM FACTURA F WHERE F.FECHA >= ? AND F.FECHA <= ? ORDER BY F.FOLIO"

           apCode   := SR_SQLParse( cSQL,@nError,@nPos )
           cResult  := SR_SQLCodeGen( apCode, {dFECINI,dFECFIN}, SYSTEMID_MSSQL7 )

           aRet :={}
           oSql := SR_GetConnection()
           oSql:exec( cResult,,.t.,@aRet)

           IF len(aRet) > 0

              oFr:SetUserDataSet( "aRet","FACTURA;FECHA;EXENTAS;GRAVADAS;IVAS;TOTALES;STA",;
                     {||np := 1}       ,;            //--> bGoTop
                     {||np := np + 1}  ,;            //--> bSkipPlus
                     {||np := np - 1}  ,;            //--> bSkipMinus
                     {||np > Len(aRet)},;            //--> bCheckEOF
                     {|aField|nCol := IIF( aField == "FACTURA"      , 1,;
                                      IIF( aField == "FECHA"        , 2,;
                                      IIF( aField == "EXENTAS"      , 3,;
                                      IIF( aField == "GRAVADAS"     , 4,;
                                      IIF( aField == "IVAS"         , 5,;
                                      IIF( aField == "TOTALES"      , 6,;
                                      IIF( aField == "STA"          , 7, ))))))), aRet[np, nCol] } )

                IF .NOT. oFR:LOADFROMFILE("REPORTE DE FACTURAS.FR3")
                   PLSWAIT(.T.,"Problema cargando el reporte ...")
                   inkey(2)
                   PLSWAIT(.F.)
                ELSE
                   oFR:PreviewOptions:SetMaximized(.f.)
                   oFR:PreviewOptions:SetBounds(120, 120, 800, 600)
                   oFR:PreviewOptions:SetModal(.f.)
                   oFR:SHOWREPORT()
                ENDIF
           ELSE
                PLSWAIT(.T.,"No existen facturas a esta fecha ...")
                inkey(2)
                PLSWAIT(.F.)
           Endif
        ENDDO
        oFr:DestroyFR()
Return