PC Toledo

Código: Selecionar todos

Function Main()
   Local oShell

   oShell := CreateObject( "WScript.Shell" )
   oShell:run("chrome.exe https://api.whatsapp.com/send?phone=34666666666" )
   Sleep(1500)
   oShell:sendkeys("{tab}{tab}")
   oShell:SendKeys("~")
   Sleep(5000)
   oShell:sendkeys("Mensaje de prueba")
   oShell:SendKeys("~")

Return nil
 

Código: Selecionar todos

********************************************************************************	
FUNCTION EXEMPLO_API_WHATS()
	LOCAL oWhats := TWhatsappAPI_WTS():New()
	oWhats:Situacao()
	oWhats:NivelBateria()
	oWhats:NrConectado()
	oWhats:EnviarMsg('5567992354872', 'Teste *mensagem*')
	oWhats:EnviarMsg('5567992354872', NIL, 'd:\documento.pdf') ; Inkey(2)  // PAUSAR UNS 2 SEGUNDOS ENTRE UMA MENSAGEM E OUTRA
	oWhats:EnviarMsg('5567992354872', NIL, 'd:\imagem.png')      ; Inkey(2)
	oWhats:End()
Quit()

********************************************************************************
#DEFINE httpGet  1
#DEFINE httpPost 2

********************************************************************************
CLASS TWhatsappAPI_WTS

		DATA sToken    INIT 'O TOKEN Q VC ADQUIRIR OU PEDE PRO HENDELL PRA TESTES'
		DATA sEndPoint INIT 'URL DO ENDPOINT Q ELE FORNECE PRA TESTES QDO VC TIVER O SEU SERA O SEU URL, VC NAO USA ESTRUTURA DELE E SIM A SUA'

		DATA sRet      INIT ''
		DATA hHash     INIT hb_Hash()
		DATA nMetodo   INIT 0  // 1 GET 2 POST

		METHOD ComunicaAPI()
		METHOD Situacao()
		METHOD Obter_QRCode()
		METHOD NrConectado()
		METHOD NivelBateria()
		METHOD EnviarMsg()
		METHOD MostraRetorno() INLINE PTAlert( 'Codigo..:;'+	PADC( hb_cStr(::hHash['codigo'],70)    ) +';' +;
													      'Mensagem:;'+  PADC( UPPER(ALLTRIM(hb_UTF8ToStr(hb_cStr(::hHash['mensagem'])))),70) +';' +;
													    	'Retorno.:;'+	PADC( hb_cStr(::hHash['retorno'],70)   ), aOk, vcroxo)

//		METHOD WhatsAPI_SetarWebhook() // PRA LER O RETORNO DAS MENSAGENS, ESSA PARTE NAO FIZ AINDA.

		Method End() INLINE Self := Nil
ENDCLASS

*******************************************************************************
METHOD Situacao() Class TWhatsappAPI_WTS
	Mensag("Consultando situacao da API...")
	::ComunicaAPI("/whatsapp/situacao", httpGet)

	If 'false' $ ::hHash['retorno']
		MsgInfo( "Nao conectado. Obtenha QRCode", 'Atenção' ) 
	Else
		MsgInfo( "Whatsapp ja esta conectado.", 'Atenção' ) 
	EndIf
Return  

*******************************************************************************
METHOD NivelBateria() Class TWhatsappAPI_WTS
	Mensag("Consultando nivel bateria")
	::ComunicaAPI("/whatsapp/bateria", httpGet)
	::MostraRetorno()
*******************************************************************************
METHOD NrConectado() Class TWhatsappAPI_WTS
	Mensag("Consultando Nr Conectado API...")
	::ComunicaAPI("/whatsapp/meunumero", httpGet)
	::MostraRetorno()
Return  
********************************************************************************
METHOD EnviarMsg(sContato, sMsg, sFilename) Class TWhatsappAPI_WTS
	LOCAL sURL 
	DEFAULT sMsg TO ''
	DEFAULT sFilename TO ''
	IF EMPTY(sFilename) .AND. EMPTY(sMsg)
		Alert('falta parametro')
		RETURN
	ENDIF
	IF EMPTY(sFilename)
		Mensag("Enviando mensagem de texto...")
		sURL := "/whatsapp/msg"
	ELSE
		Mensag("Enviando arquivo...")
		sURL := "/whatsapp/arquivo"
	ENDIF
	::ComunicaAPI(sURL, httpPost, sContato, sMsg, sFilename)
	::MostraRetorno()
********************************************************************************
Procedure Obter_QRCode() Class TWhatsappAPI_WTS
	Mensag("Obtendo QRCode...")
	::ComunicaAPIWhats('/whatsapp/qrcode', httpGet)

// ATEN€ÇO O RETORNO AKI  RETORNADO O QRCODE EM Q VC TEM Q CARREGAR UM OBJETO GRAFICO ATRAVES DE UMA LIB GRAFICA FIVEWIN, XAILER, MINIGUI, HWGUI ETC
//     If 'obtido com sucesso' $ ::hHash['mensagem'] 
//			AKI CARREGA O OBJETO GRAFICO NA LIB Q VC USAR ::hHash['retorno'], { 20,20,-20,-20 }, "QR-CODE" 
//     Else
//        MsgInfo( "O Whatsapp esta reiniciando. Favor repetir a operação.", 'Atenção' )            
//     EndIf            
Return 
*------------------------------------------------------------------------------*

METHOD  ComunicaAPI(sURL, nMetodo, sContato, sMsg, sFilename) Class TWhatsappAPI_WTS
	LOCAL cMetodo, oWeb, sContent := ''
	TRY
		oWeb  := CreateObject( 'MSXML2.ServerXMLHTTP.6.0' ) 
	CATCH
		oWeb  := CreateObject( 'MSXML2.XMLHTTP' )
	END
	IF EMPTY(sContato) .AND. nMetodo = httpPost  
		Alert("Falta telefone")
		RETURN NIL
	END
	
	sURL    := ::sEndPoint + sURL  
	cMetodo := IIF( nMetodo == httpGet, 'GET', 'POST')
	oWeb:Open( cMetodo, sUrl,  .F.)  // True = pra vir o ResponseBody 
   oWeb:SetRequestHeader( 'token', ::sToken )

	IF nMetodo = httpPost
		oWeb:setRequestHeader( "contato", sContato )
		IF .NOT. EMPTY(sFilename)
			oWeb:setRequestHeader( "filename", SUBSTR(ALLTRIM( CharRem( "[<(-)>]*&@:", sFileName ) ),2))
			oWeb:setRequestHeader( "caption",  SUBSTR(ALLTRIM( CharRem( "[<(-)>]*&@:", sFileName ) ),2)) 
			
			sContent = hb_MemoRead(sFileName)
			sContent = hb_base64encode(sContent)
			sContent = hb_StrToUTF8(sContent)
			sContent = ALLTRIM( CharRem( CRLF, sContent ) )
		ELSE
			IF .NOT. EMPTY(sMsg)
				sContent = sMsg
			ENDIF
		END
      oWeb:setRequestHeader( "Content-Type", "text/plain; charset=UTF-8" )
	END
	TRY
		IF EMPTY(sContent)
			oWeb:Send(  )  
		ELSE
			oWeb:Send( sContent )  
		ENDIF
		::sRet := oWeb:ResponseBody()
		hb_jsondecode( ::sRet, @::hHash )
	CATCH ; END
  RETURN NIL

Código: Selecionar todos

#include "hbcurl.ch"

PROCEDURE Main()
   LOCAL hCurl, cURL, cToken, cInstance, cPhone, cMsg, cPostData, nRet

   // Token e ID fornecidos pela UltraMsg
   cInstance := "instanceXXXX"    // Ex: instance12345
   cToken    := "your-token"      // Ex: abcdefghijklmnopqrstuvwxyz
   cPhone    := "5511999999999"   // Número com DDI + DDD (sem + ou traços)
   cMsg      := "Olá Clodoaldo, esta é uma mensagem automática do Harbour!"

   // Monta a URL da API
   cURL := "https://api.ultramsg.com/" + cInstance + "/messages/chat"

   // Monta os dados a serem enviados (formato x-www-form-urlencoded)
   cPostData := "token=" + cToken + ;
                "&to=" + cPhone + ;
                "&body=" + hb_urlEncode(cMsg)

   // Inicializa o cURL
   hCurl := hb_curl_easy_init()

   IF hCurl != NIL
      hb_curl_easy_setopt( hCurl, HB_CURLOPT_URL, cURL )
      hb_curl_easy_setopt( hCurl, HB_CURLOPT_POSTFIELDS, cPostData )
      hb_curl_easy_setopt( hCurl, HB_CURLOPT_WRITEFUNCTION, { |x| QOut("Resposta: " + x), 0 } )

      // Executa a requisição
      nRet := hb_curl_easy_perform( hCurl )

      // Libera recursos
      hb_curl_easy_cleanup( hCurl )

      IF nRet == 0
         ? "Mensagem enviada com sucesso!"
      ELSE
         ? "Erro ao enviar mensagem. Código:", nRet
      ENDIF
   ELSE
      ? "Erro ao inicializar o cURL"
   ENDIF
RETURN