PC Toledo

Código: Selecionar todos

AAdd( aDados, {;
   mCodigo,;
   HB_AnsiToOem( rs:Fields( 8 ):Value ),;
   '',;  //Portaria
   '',;  //Descricao
   '';
    })

Código: Selecionar todos

Examples

     .  This example creates a one-dimensional array of five elements
        using the ARRAY() function, and then shows the equivalent action by
        assigning a literal array of NIL values:

        aArray := ARRAY(5)
        aArray := { NIL, NIL, NIL, NIL, NIL }

     .  This example shows three different statements which create the
        same multidimensional array:

        aArray := ARRAY(3, 2)
        aArray := { {NIL, NIL}, {NIL, NIL}, {NIL, NIL} }
        aArray := { ARRAY(2), ARRAY(2), ARRAY(2) }

     .  This example creates a nested, multidimensional array:

        aArray := ARRAY(3, {NIL,NIL})

Código: Selecionar todos

Proc Main()

   LOCAL aArray := Array( 1000, 3 )

   CLS

   hb_alert( aArray[1000, 3 ] )   // NIL

RETURN

Código: Selecionar todos

////////////////////////////////////////////////////////////////////////////////
//Links úteis
// Link para Excel: http://fivewin.com.br/index.php?/topic/21673-usando-o-createobject-excelapplication/
// Link instalar Access: https://learn.microsoft.com/en-us/answers/questions/296080/how-to-fix-microsoft-ace-oledb-12-0-provider-is-no
// Tem muita coisa aqui no Forum sobre o assunto



Begin sequence
   ...
   ...

   //Planilha a abrir
   mArq_ := 'c:\minha Pasta\Planilha.xlsx'

   TRY   //Cria um objeto de conexão

      oConexao := CreateObject( "ADODB.Connection" )

   CATCH oError
      wvw_messagebox( , 'ERRO...: TER/008'+CRLF+;
       'Aviso..:O MS.Excel não esta Ativado ou Não instalada nesse Computador.'+CRLF+;
       'Instale o MS Excel para continuar com a exportação dos dados.'+CRLF+;
       cl_getError(oError),;
       MB_OK|MB_ICONERROR )
      //lOk:=.f.
      Break
   END

   //Abrindo a PLanilha
      If ".XLSX" $ Upper(mArq_)
         oConexao:ConnectionString := ;
          [Provider=Microsoft.ACE.OLEDB.12.0;Data Source=] + mArq_ +;
          [;Extended Properties="Excel 12.0 Xml; HDR=Yes";] //IMEX=1";]
       Else
         oConexao:ConnectionString := ;
          [Provider=Microsoft.Jet.OLEDB.4.0;Data Source=] + mArq_ +;
          [;Extended Properties="Excel 8.0; HDR=Yes";]
       Endif

   TRY

      oConexao:Open()

   CATCH oError  //Aqui vc pode colocar suas mensagens e rotinas de erros
      msg := 'ERRO...: FUS/009'+CRLF
      msg += 'Aviso..:Não consegui abrir a planilha (XLS) SICONFI na pasta: ' + mArq_ + CRLF
      msg += cl_getError(oError, .t.)
      MsgError( msg, .t.)
      lOk:=.f.
      Break
   END

   //Abrindo a Sheet, fazendo um Select, padrão SQL
   TRY

      rs := oConexao:Execute( "SELECT * FROM ['MinhaPasta$']" ) //vc deve colocar o no da pasta sucedido de um "$"

   CATCH oError
      wvw_messagebox( , 'ERRO...: TER/030'+CRLF+;
       'Aviso..:Não consegui abrir a primeira da planilha de Receitas do STN: ' + mArq_ + CRLF+;
       'Verifique se na planilha selecionada existe a Pasta.'+CRLF+;
       cl_getError(oError),;
       'ATENÇÃO! '+UserName, MB_OK|MB_ICONERROR )
      //lOK:=.f.
      Break
   END

   aDados:={}
   Do While !rs:Eof() .and. poe_gauge()

      IF IN_KEY()=K_ESC 		                            // se quer cancelar
         msg:='Deseja encerrar a operação?'
         IF MsgYesNo( msg )
            BREAK                                         // confirmou...
         ENDIF
      ENDIF

      If !Empty( rs:Fields( 7 ):Value ) //a primeira coluna da planilha começa com "0" na resultado do Select. A coluna "A" vai ser "0", a "B" vai ser "1" ...

         //ajustes que faço na minha rotina
         mCodigo := Left(StrTran( AllTrim( Str( rs:Fields( 7 ):Value ) ), '.', ''), 8)

         mDescricao := StrTran(HB_AnsiToOem( rs:Fields( 10 ):Value ), Chr(10), '')
         mDescricao := AllTrim(StrTran(mDescricao, Chr(13), ''))
         mDescricao := AllTrim(StrTran(mDescricao, CRLF, ''))

         mNorma := StrTran(HB_AnsiToOem( rs:Fields( 11 ):Value ), Chr(10), '')
         mNorma := AllTrim(StrTran(mNorma, Chr(13), ''))
         mNorma := AllTrim(StrTran(mNorma, CRLF, ''))

         //Adicionando resultados na Array
         AAdd( aDados, {;
          mCodigo,;
          HB_AnsiToOem( rs:Fields( 8 ):Value ),;
          HB_AnsiToOem( rs:Fields( 9 ):Value ),;   //Portaria
          mDescricao,;                             //Descricao
          mNorma;
          })

         //Se tiver passando dados pra um DBF:
         If "Condições"
         
            Append Blank
            
            Field->campo1 := rs:Fields( 0 ):Value
            Field->campo2 := rs:Fields( 1 ):Value
            Field->campo3 := rs:Fields( 2 ):Value
            
         Endif

      Endif

      rs:MoveNext()  //Vai pro próximo registro

   Enddo
   rs:Close() //Fecha o Select

   oConexao:Close()  //Fecha Cnexão

End Sequence
//Não fiz o testa da rotina acima, mas qq erro basta poucos ajustes.
//Agumas funções que uso no exemplo, vc pode substituir por outras.