PC Toledo

Código: Selecionar todos

// C:\FWH\SAMPLES\DETLEF.PRG

#include "FiveWin.ch"

FUNCTION Main()

   LOCAL oDlG, oDate, oStatMonth, oStatYear, oBtn
   LOCAL hData := { => }

   SET CENTURY ON
   SET EPOCH TO Year( Date() ) - 30
   Set( _SET_DATEFORMAT, "dd.mm.yyyy" )

   hData[ "date"       ] := Date()
   hData[ "stat_month" ] := Month( Date() )
   hData[ "stat_year"  ] := Year(  Date() )

   DEFINE DIALOG oDlg NAME "DATE_DLG"

   REDEFINE GET oDate VAR hData[ "date" ]    ;
      ID 10 OF oDlg PICTURE "@D"             ;
      BITMAP ""                              ;
      UPDATE                                 ;
      ACTION ( hData[ "date" ] := dGetCal(), ;
      oDate:Refresh(),                       ;
      hData[ "stat_month" ] := Month( hData[ "date" ] ), ;
      hData[ "stat_year"  ] :=  Year( hData[ "date" ] ), ;
      oStatMonth:Refresh(), oStatYear:Refresh(), ;
      oDate:SetFocus() )                         ;
      ON CHANGE ( hData[ "stat_month" ] := Month( hData[ "date" ] ), ;
                  hData[ "stat_year"  ] :=  Year( hData[ "date" ] ), ;
                  oStatMonth:Refresh(), oStatYear:Refresh() )

   REDEFINE GET oStatMonth VAR hData[ "stat_month" ] ;
      ID 20 OF oDlg PICTURE "99"                     ;
      SPINNER MIN 1 MAX 12                           ;
      UPDATE

   REDEFINE GET oStatYear  VAR hData[ "stat_year"  ] ;
      ID 30 OF oDlg PICTURE "9999";
      SPINNER MIN ( Year( Date() ) - 20 );
      MAX ( Year( Date() ) + 20 );
      UPDATE

   REDEFINE BUTTON oBtn ID IDCANCEL OF oDlg ACTION oDlg:End()

   ACTIVATE DIALOG oDlg CENTERED

RETURN NIL

STATIC FUNCTION dGetCal()

RETURN( CToD( "24.12.2008" ) )

/*  //-> SALVE COMOM: DETLEF.RC

DATE_DLG DIALOG DISCARDABLE 6, 18, 158, 70
STYLE WS_CAPTION|WS_SYSMENU|WS_MINIMIZEBOX|WS_MAXIMIZEBOX|WS_VISIBLE
CAPTION "Dialog"
FONT 10, "MS Sans Serif"
{
  CONTROL "Date", -1, "Static", WS_GROUP, 8, 12, 24, 9
  CONTROL "", 10, "Edit", ES_CENTER|WS_BORDER|WS_TABSTOP, 8, 24, 54, 11, WS_EX_RIGHT|0x00010000
  CONTROL "Statistic-Month-Year", -1, "Static", WS_GROUP, 76, 12, 64, 9
  CONTROL "", 20, "Edit", ES_AUTOHSCROLL|WS_VSCROLL|WS_BORDER|WS_TABSTOP, 76, 24, 24, 11
  CONTROL "", 30, "Edit", ES_CENTER|WS_VSCROLL|WS_BORDER|WS_TABSTOP, 108, 24, 40, 11
  CONTROL "Cancel", IDCANCEL, "Button", WS_TABSTOP, 100, 48, 48, 14
}

*/
// FIN / END

Código: Selecionar todos

// C:\FWH\SAMPLES\GUNTHER2.PRG

#include "FiveWin.ch"

FUNCTION test()

   LOCAL oDlg, oFld, oGet, cCombo, cTest := "Hello world", cAnother := "Another GET"
   LOCAL oBtn

   SetDlgGradient( { { 1, RGB( 199, 216, 237 ), RGB( 237, 242, 248 ) } } )

   DEFINE DIALOG oDlg TITLE "Quintas Test FOLDEREX" SIZE 400, 300

   @ 3, 5 FOLDEREX oFld PIXEL PROMPT "&One", "&Two", "&Three" SIZE 190, 120

   @ 1, 1 GET oGet VAR cTest OF oFld:aDialogs[ 1 ] COLOR CLR_HRED, CLR_HCYAN

   @ 2, 1 COMBOBOX cCombo PROMPTS { "A", "B", "C" } OF oFld:aDialogs[ 1 ]

   @ 4, 1 GET cAnother OF oFld:aDialogs[ 1 ] COLOR CLR_HRED, CLR_HCYAN

   // @ 5, 1 SAY cTest OF oFld:aDialogs[ 1 ]

   @ 7.2, 14 BUTTON oBtn PROMPT "Ok" ;
      ACTION MsgRun( "This is a test", "MsgRun test", {|| WaitSeconds( 5 ) } )

   ACTIVATE DIALOG oDlg CENTERED ON INIT ( oGet:SetFocus(), .F. )

RETURN NIL

// FIN / END

Código: Selecionar todos

// C:\FWH\SAMPLES\QUINTAFL.PRG - USANDO FOLDEREX e mais...

#include "FiveWin.ch"

FUNCTION Main()

   LOCAL oDlg, oFld, oGet, cCombo, cTest := "Hello world", cAnother := "Another GET"
   LOCAL oBtn, oExit, oFont, oFnt, cQuintas := "QUINTAS E O CARA"

   SkinButtons()

   // SetDlgGradient( { { 1, RGB( 199, 216, 237 ), RGB( 237, 242, 248 ) } } )

   DEFINE FONT oFont NAME "Ms Sans Serif" SIZE 00, -14 BOLD
   DEFINE FONT oFnt  NAME "Ms Sans Serif" SIZE 00, -12 BOLD

   DEFINE DIALOG oDlg TITLE "Quintas Test FOLDEREX" SIZE 400, 300 FONT oFont

   oDlg:lHelpIcon := .F.

   @ 3, 5 FOLDEREX oFld PIXEL PROMPT "&One", "&Two", "&Three" SIZE 190, 120 ;
      TAB HEIGHT 30 ROUND 5 FONT oFont COLOR METRO_ORANGE TOP

   WITH OBJECT oFld

      :lTransparent := .T.
      :aGradSel   := { { 1.0, 3926784, 16777215 }, { 0.1, 3926784, 16777215 } } // Green
      :aGradUnSel := { { 1.0, 16744448, 16777215 }, { 0.1, 16744448, 16777215 } } // Blue
      :aGradOver  := { { 1.0, 255, 16777215 }, { 0.1, 255, 16777215 } } // Red
      :aGradOverUnSel := { { 1.0, 12824535, 16777215 }, { 0.1, 12824535, 16777215 } } // Purple
      :aGradDis := { { 1.0, 15790320, 16777215 }, { 0.1, 15790320, 167772 } }
      //
      :SetOption( 1 )
      :aEnable = { .T., .T., .T., .F. } // liga / desliga folders
      :Show()
      // :DisableTab( 3 )  // idem a :aEnable
      // :oCursor := oHand  // PEGAR DO ARQUIVO DE RECURSOS.RES/RC

   END

   @ 1, 1 GET oGet VAR cTest OF oFld:aDialogs[ 1 ] COLOR METRO_RED, CLR_WHITE

   @ 2, 1 COMBOBOX cCombo PROMPTS { "A", "B", "C" } OF oFld:aDialogs[ 1 ]

   @ 4, 1 GET cAnother OF oFld:aDialogs[ 1 ] COLOR METRO_RED, CLR_WHITE

   @ 5, 1 SAY cTest OF oFld:aDialogs[ 2 ]  COLOR METRO_RED, CLR_WHITE

   @ 5, 1 SAY cQuintas OF oFld:aDialogs[ 3 ] COLOR METRO_RED, CLR_WHITE

   @ 7.2, 10 BUTTON oBtn PROMPT "Ok" ;
      ACTION MsgRun( "This is a test", "MsgRun test", {|| WaitSeconds( 5 ) } )

   @ 7.2, 20 BUTTON oExit PROMPT "&Exit" ACTION( oDlg:End ) CANCEL

   ACTIVATE DIALOG oDlg CENTERED ON INIT ( oGet:SetFocus(), .F. )

   oFont:End()
   oFnt:End()

RETURN NIL

// FIN / END - kapiabafwh@gmail.com

Código: Selecionar todos

testfx1.prg
testfx3.prg
testfx3.rc
testfx3.RES
TESTFX4.PRG
testfx5.prg
TESTFX6.PRG
testfx8.prg
testfx8.rc
testfx8.RES 

Código: Selecionar todos

   IF gui_LibName() == "FIVEWIN"
      FOR EACH aControl IN ::aControlList
         IF aControl[ CFG_FCONTROL ]:ClassName() == "TGET"
            aControl[ CFG_FCONTROL ]:nHeight := APP_LINE_HEIGHT
         ENDIF
   ENDIF