PC Toledo

Código: Selecionar todos

function cFileName( cPathMask )
    return cFileNoPath( cPathMask )
     
function cFileNoPath( cPathMask )  // returns just the filename no path
    local n := RAt( "\", cPathMask )
    return Upper( If( n > 0 .and. n < Len( cPathMask ),;
                  Right( cPathMask, Len( cPathMask ) - n ),;
                  If( ( n := At( ":", cPathMask ) ) > 0,;
                      Right( cPathMask, Len( cPathMask ) - n ),;
                      cPathMask ) ) )
     
function cFileDisc( cPathMask )  // returns drive of the path
     return If( At( ":", cPathMask ) == 2, ;
           Upper( Left( cPathMask, 2 ) ), "" )
     
function cFilePath( cPathMask )   // returns path of a filename
     local n := RAt( "\", cPathMask )
     return If( n > 0, Upper( Left( cPathMask, n ) ),;
           cFileDisc( cPathMask ) + "\" )
     
function cFileMask( cPathMask )  // returns mask of a filename
     local cMask := cFileNoPath( cPathMask )
     return If( ( "*" $ cMask ) .or. ( "?" $ cMask ), cMask, "" )
     
function cFileNoExt( cPathMask ) // returns the filename without ext
     local cName := AllTrim( cFileNoPath( cPathMask ) )
     local n     := At( ".", cName )
     return AllTrim( If( n > 0, Left( cName, n - 1 ), cName ) )
     
function cFileExt( cPathMask ) // returns the ext of a filename
     local cExt := AllTrim( cFileNoPath( cPathMask ) )
     local n    := RAt( ".", cExt )
     return AllTrim( If( n > 0 .and. Len( cExt ) > n,;
                    Right( cExt, Len( cExt ) - n ), "" ) )
     
function cFileSubDir( cPath )   // returns the subdir of a path & filename
     return Upper( cFilePath( If( Right( cPath, 1 ) == "\" ,;
              Left( cPath, Len( cPath ) - 1 ), cPath ) ) )
     
function FSize( cFile ) // returns the size of filename
     local aFiles := Directory( cFile )
     If Len( aFiles ) > 0
        return aFiles[ 1 ][ 2 ]
     endif
     return 0
     
function FDate( cFile ) // returns the date of filename
     local aFiles := Directory( cFile )
     If Len( aFiles ) > 0
        return aFiles[ 1 ][ 3 ]
     endif
     return CToD( "  -  -  " )
     
function FTime( cFile ) // returns the time of filename
     local aFiles := Directory( cFile )
     If Len( aFiles ) > 0
        return aFiles[ 1 ][ 4 ]
     endif
     return ""