PC Toledo

Código: Selecionar todos

#include "inkey.ch"
#include "hwgui.ch"
#include "fileio.ch"
#include "common.ch"
#include "Directry.ch"

#define eFTPSERVER1  'ftp.servidor.com.br'        // ENDEREÇO SERVIDOR FTP  01
#define eFTPPORTA   21                            // PORTA DO FTP PARA BAIXAR ATUALIZAÇÕES DO SISTEMA
#define eFTPUSER    'usuario'                     // USUARIO DO FTP PARA BAIXAR ATUALIZAÇÕES DO SISTEMA
#define eFTPPASS    'senha'                       // SENHA DO FTP PARA BAIXAR ATUALIZAÇÕES DO SISTEMA


FUNCTION MAIN()
local aDir0, nTAMANHO:=0

aDir0 := directory('sistema.exe')
nTAMANHO:=aDir0[1,2]

IF UPLOAD_ARQ( "/pasta_destino", nTAMANHO, 'sistema.exe' ) = .F.
   MsgInfo('Enviou para ftp com sucesso')
ENDIF

RETURN NIL

********************************************************************
STATIC FUNCTION UPLOAD_ARQ( FTPDIR, cTamanho, farq )
********************************************************************
Local cUrl, oUrl, oFTP, cFTPSERVER:=''

cFTPSERVER:=eFTPSERVER1
cUrl := "ftp://" + eFTPUSER + ":" + eFTPPASS + "@" + cFTPSERVER

oUrl              := tUrl():New( cUrl )
oFTP              := tIPClientFtp():New( oUrl, .F. )
oFTP:nConnTimeout := 20000
oFTP:bUsePasv     := .T.
oFTP:nDefaultPort := eFTPPORTA   //PORTA DO FTP
oFTP:oUrl:cUserID := eFTPUSER
oFTP:oUrl:cServer   := cFTPSERVER
oFTP:oUrl:cPassword := eFTPPASS

IF oFTP:Open( cUrl )
   IF !oFTP:Cwd(ftpdir)  // se não achar o diretorio ele cria
      oFTP:MKD(ftpdir)     // muda o diretorio
   ENDIF
   oFTP:Cwd(ftpdir)     // muda o diretorio
   oFTP:reset()

   oFtp:exGauge := { | done | oSAY1:SETTEXT("Enviando Arquivo: "+ farq + STR((done/cTamanho)*100,4)+" %") }
   oFtp:UploadFile( farq )

   Millisec(1000)

   oFTP:Close()  // fehca a conexão do FTP
ELSE
   RETURN .F.
ENDIF
RETURN .T.

Código: Selecionar todos

***************
FUNCTION MAIN()
***************
Local cURL, lRet:=.F.
Local nTAMANHO:=0
LOCAL  oConn

cURL := "http://www.meusite.com.br/arquivo.rar"

nTAMANHO := GET_FILE_SIZE('arquivo.rar') // aqui uso uma função em PHP para pegar o tamanho do arquivo

TRY
  oConn := TipClientHttp():New(TURL():New(cURL))
  oConn:nConnTimeout := 10000
  oConn:exGauge := { | done, size| ShowGauge(done, size, nTAMANHO ) }

  IF oConn:Open(cURL)
     oConn:ReadToFile('c:\salva_nessa_pasta\nome_do_arquivo.rar')
     oConn:Close()
  ENDIF
  lRet:=.T.
CATCH
  lRet:=.F.
END
RETURN(lRet)

******************************************
PROCEDURE SHOWGAUGE( nSent, nSize, nTotal)
******************************************
IF nSent > 0
   @ 10,10 SAY STR(nSent/1000000)+" Mb de: " + str(nTotal/1000000)+ " Mb "+str((nSent/nTotal)*100,4) +" %"
ENDIF
RETURN

************************************
FUNCTION GET_FILE_SIZE(cCAMINHO_URL)
************************************
LOCAL nRET_BYTS:=0
LOCAL oHttp, cHtml:=''

IF Empty( cCAMINHO_URL )
   Return(nRET_BYTS)
ENDIF

TRY
   oHttp:= TIpClientHttp():new( "http://www.meusite.com.br/tamanhoArquivo.php?caminho="+alltrim(cCAMINHO_URL))
CATCH
   Return(nRET_BYTS)
END
IF oHttp:open()
   cHtml   := oHttp:readAll()

   IF !EMPTY(cHtml)
      IF LEN(cHTML) > 0 .AND. LEN(cHTML) < 20
         nRET_BYTS:=VAL(alltrim(cHTML))
      ENDIF
   ENDIF
ENDIF
oHttp:close()
RETURN(nRET_BYTS)