PC Toledo

Código: Selecionar todos

STATIC PROC MONTA_LIN(qtlin_,qttab_)  // le/imprime linhas do arquivo binario
LOCAL t_, i_, x_, j_, lin_, buf_, tambuf_, ini_, fim_, qts_:=0,;
      tp_cmd:="pcomtcompc20tc20pelitelipenftenfpexptexppde8tde8landport"
IF qtlin_!=0                                     // quer le outras linhas?
   tambuf_=MIN(ABS(qtlin_)*2700,32000)           // buffer maximo do tamnho das linhas
   IF qtlin_<0 .AND. offset_ini>1                // quer voltar linhas e nao esta no topo
      IF offset_ini<tambuf_                      // se o tamanho buffer e maior do que
         tambuf_=offset_ini                      // ja foi lido, ajusta seu tamanho
      ENDI
      FSEEK(area_,offset_ini-tambuf_)            // posiciona poteiro para a leitura
      buffer_=SPAC(tambuf_)                      // inicializa o buffer e
      FREAD(area_,@buffer_,tambuf_)              // le o arquivo...
      buffer_=STRTRAN(buffer_,CHR(12)+CHR(13),CHR(13)+CHR(10))
      tambuf_++                                  // incrementa tamanho do buffer
      buf_=tambuf_                               // salva tamanho original
      FOR t_ = qtlin_ TO -1                      // faz p/ todas as linhas requeridas
         IF tambuf_ > 1                          // se nao esta no inicio do buffer
            tambuf_-=3                           // tira o CR+LF do fim da linha
            i_=tambuf_                           // acha o ultimo CR+LF
            tambuf_=RAT(CHR(13)+CHR(10),SUBS(buffer_,1,tambuf_))
            tambuf_=IF(tambuf_>0,tambuf_+2,1)    // se achou desconta o CR+LF
            IF l_arq[maxlin_]!=CHR(0)            // se a linha a excluir for do arquivo
               offset_fim-=LEN(l_arq[maxlin_])+2 // decrementa seu tamanho do offset do
            ENDI                                 // fim do arquivo (acresentando o CR+LF)
            AINS(l_arq,1)                        // insere um linha no top do arranjo
            i_=i_-tambuf_+1
            l_arq[1]=SUBS(buffer_,tambuf_,i_)    // inicializa a linha com a linha do arq
            qts_--                               // qtde de linhas do scroll
         ELSE                                    // se chegou no inicio do tamanho do
            EXIT                                 // buffer lido, cai fora...
         ENDI
      NEXT
      offset_ini-=buf_-tambuf_                   // ajusta offset da linha inicio da janela

   ELSEIF l_arq[2]!=CHR(0)                       // quer avancar linhas e nao esta no fim do arq
      FSEEK(area_,offset_fim)                    // posiciona o ponteiro na ultima lin lida
      IF offset_fim+tambuf_>fim_arq_             // se o resto do arquivo e menor do que
         tambuf_=fim_arq_-offset_fim             // o tamanho do buffer, ajusta seu tamanho
      ENDI
      buffer_=SPAC(tambuf_)                      // inicializa o buffer e
      FREAD(area_,@buffer_,tambuf_)              // le o arquivo...
      buffer_=STRTRAN(buffer_,CHR(12)+CHR(13),CHR(13)+CHR(10))
      FOR t_ = 1 TO qtlin_                       // mostra proximas linhas requeridas
         IF l_arq[1]!=CHR(0)                     // se for uma linha lida do arquivo
            offset_ini+=LEN(l_arq[1])+2          // ajusta offset do inicio
         ENDI
         ADEL(l_arq,1)                           // apaga a 1a. linha do arranjo
         qts_++                                  // qtde de linhas que sera feita o scroll
         IF LEN(buffer_)<3                       // se nao tem mais linha para montar a tela
            l_arq[maxlin_]=""   // CHR(0) 
***
**     se colcar chr(0) ficava ponto de interrogacao na tela
**
            IF l_arq[2]=CHR(0)                   // se o fim do arq esta na 1a. linha
               EXIT                              // nao tem mais linha para mostrar
            ENDI
         ELSE                                    // caso contrario pega linha corrente
            l_arq[maxlin_]=PARSE(@buffer_,CHR(13)+CHR(10))
            offset_fim+=LEN(l_arq[maxlin_])+2    // ajusta offset do fim da janela
         ENDI
      NEXT
   ENDI
ENDI
i_=0
FOR t_ = 1 TO maxlin_                            // pega o tamanho da maior linha
   i_=MAX(i_,LEN(l_arq[t_]))
NEXT
IF (qttab_<0 .AND. tablin_>1) .OR.;              // quer rolar horizontalmente?
   (qttab_>0 .AND. tablin_<i_-10)
   tablin_+=qttab_                               // soma/diminui tabulacao atual
   qts_=maxlin_                                  // forca remontagem de toda a janela
ENDI
IF qts_!=0                                       // se leu alguma linha
   SCROLL(lsup_,csup_,linf_,cinf_,qts_)          // rola a tela
   ini_=IF(qts_>0,maxlin_-qts_+1,1)              // inicio e fim das linhas
   fim_=IF(qts_>0,maxlin_,ABS(qts_))             // que foram lidas
   i_=cinf_-csup_+1                              // tamanho da janela
   FOR t_=ini_ TO fim_                           // imprime linhas lidas
      lin_=l_arq[t_]
      IF !EMPTY(lin_) .AND.!OK_PRINT(lin_)        // tem caraceter de controle?
         IF AT(" "+CHR(8),lin_)>0                // tira efeito especial da frente da linha
            lin_=SUBS(lin_,AT(" "+CHR(8),lin_)+2)
         ENDI
         FOR j_=1 TO 56 STEP 4                   // testa todos os carc de controle
            x_="drv"+SUBS(tp_cmd,j_,4)             // monta o nome do efeito
            x_=&x_.
            IF !EMPTY(x_)                          // tem efeito configurado?
               lin_=STRTRAN(lin_,TRANS(&x_.,""),"")   // retira-o da linha
            ENDI
         NEXT
      ENDI
      @ lsup_+t_-1,csup_ SAY SUBS(lin_,tablin_,i_)
   NEXT
ENDI
buffer_=""
RETU

Código: Selecionar todos

Function EXTENSAO(xArg1)

   Local xVar1
   xVar1:= Upper(indexext())
   xArg1:= IIf(xArg1 = Nil,.T.,xArg1)
   If (!xArg1)
      If (xVar1 = ".NSX")  // de .CDX para .NSX
         xVar1:= ".SMT"    // de .FPT para .SMT
      Else
         xVar1:= ".DBT"
      EndIf
   EndIf
   Return xVar1