Página 1 de 1
Google maps
Enviado: 21 Nov 2013 12:55
por rbonotto
Bom dia amigos,
Vi estes dias em uma empresa de moto entregas um programa ( com aparencia clipper ) onde o usuario tinha um campo de endereço de entrega, apos preenchido o programa perguntava se queria abrir o google maps, se sim abria o navegador padrão ja com o endereço no mapa.
Alguém saberia se é possivel fazer isto com o Harbour ?
Abraços,
Google maps
Enviado: 21 Nov 2013 14:22
por Toledo
Ricardo, dê uma olhada neste tópico:
gtwvw + Google Maps
Abraços,
Google maps
Enviado: 21 Nov 2013 19:28
por rbonotto
Na mosca Toledo !
Obrigado !!
Google maps
Enviado: 21 Nov 2013 19:55
por rbonotto
Segui o sample do tópico citado e apareceram estes erros:
Código: Selecionar todos
Error: Unresolved external '_hb_iCmdShow' referenced from C:\BORLAND\BCC55\LIB\G
TWVW.LIB|gtwvw
Error: Unresolved external '_hb_hPrevInstance' referenced from C:\BORLAND\BCC55\
LIB\GTWVW.LIB|gtwvw
Error: Unresolved external '_hb_gt_w32_getKbdState' referenced from C:\BORLAND\B
CC55\LIB\GTWVW.LIB|gtwvw
Error: Unresolved external '_hb_gt_w32_setKbdState' referenced from C:\BORLAND\B
CC55\LIB\GTWVW.LIB|gtwvw
Error: Unresolved external '_hb_gt_w32_getClipboard' referenced from C:\BORLAND\
BCC55\LIB\GTWVW.LIB|gtwvw
Error: Unresolved external '_hb_gt_w32_setClipboard' referenced from C:\BORLAND\
BCC55\LIB\GTWVW.LIB|gtwvw
Error: Unresolved external '_hb_hInstance' referenced from C:\BORLAND\BCC55\LIB\
GTWVW.LIB|gtwvw
hbmk2: Error: Running linker. 2
Linha de comando para compilar:
c:\minigui\harbour\bin\hbmk2 pr_hb
Conteudo do pr_hb.hbp:
Código: Selecionar todos
# ---------------------------
# Nome do Executavel
# ---------------------------
-oprgrama
# ---------------------------
# Bibliotecas
# ---------------------------
-lhbct
-lxhb
-lhbwin
-llibpng
-gtwvt
-gtwvw
# ---------------------------
# Caminhos dos Includes
# ---------------------------
-incpath=c:\minigui\harbour\include
# ---------------------------
# Caminho das Libs da MiniGui
# ---------------------------
-Lc:\minigui\harbour\lib
-inc
# ---------------------------
# Prg(s) e Rc(s)
# ---------------------------
programa.prg
# ---------------------------
# Fim
# ---------------------------
Eu só tenho a lib gtwvw, precisaria mais algum arquivo ?
Abraços
Google maps
Enviado: 21 Nov 2013 20:28
por Toledo
Ricardo, o uso das funções da GT não é tão necessário, então segue o exemplo com algumas alterações:
Código: Selecionar todos
#include "inkey.ch"
***************
FUNCTION MAIN()
***************
local oMapa, mde_uf, mpara_uf, mde_cid, mpara_cid, mde_rua, mpara_rua, mweb
setcolor( 'N/W,N/GR*,,,N/W*' )
cls
while .T.
mde_uf := mpara_uf := space(20)
mde_cid := mpara_cid := space(40)
mde_rua := mpara_rua := space(50)
@ 05, 01 say "DE :"
@ 07, 01 say "Estado ..:" get mde_uf picture "@!"
@ 08, 01 say "Cidade ..:" get mde_cid picture "@!"
@ 09, 01 say "Endereco :" get mde_rua picture "@!"
@ 11, 01 say "PARA :"
@ 13, 01 say "Estado ..:" get mpara_uf picture "@!"
@ 14, 01 say "Cidade ..:" get mpara_cid picture "@!"
@ 15, 01 say "Endereco :" get mpara_rua picture "@!"
read
if lastkey() == K_ESC
exit
endif
mde_uf := alltrim( mde_uf ) ; mpara_uf := alltrim( mpara_uf )
mde_cid := alltrim( mde_cid ); mpara_cid := alltrim( mpara_cid )
mde_rua := alltrim( mde_rua ); mpara_rua := alltrim( mpara_rua )
oMapa := win_oleCreateObject( "InternetExplorer.Application" )
mweb := "http://maps.google.com/maps?q=de " +;
mde_rua + " " + mde_cid + " " + mde_uf + " para " +;
mpara_rua + " " + mpara_cid + " " + mpara_uf
oMapa:Visible := .T.
oMapa:Navigate( mweb )
enddo
RETURN
Na compilação basta apenas a lib -lhbwin.
Abraços,
Google maps
Enviado: 21 Nov 2013 21:42
por rbonotto
Funcionando 100% !!!
Obrigado mestre !
)
Google maps
Enviado: 25 Nov 2013 19:35
por rbonotto
Ja abusando um pouquinho....
Existe uma forma de que o navegador padrão seja utilizado, ou somente o Internet Explorer pela chamada win_oleCreateObject ?
Google maps
Enviado: 25 Nov 2013 21:02
por Toledo
Ricardo, com o win_oleCreateObject é somente o Internet Explorer, mas você pode tentar o seguinte:
Código: Selecionar todos
#include "inkey.ch"
Proc Main()
Local cDirFirefox:="C:\Arquivos de programas\Mozilla Firefox\firefox.exe"
Local oMapa, mde_uf, mpara_uf, mde_cid, mpara_cid, mde_rua, mpara_rua, mweb
setcolor( 'N/W,N/GR*,,,N/W*' )
cls
while .T.
mde_uf := mpara_uf := space(20)
mde_cid := mpara_cid := space(40)
mde_rua := mpara_rua := space(50)
@ 05, 01 say "DE :"
@ 07, 01 say "Estado ..:" get mde_uf picture "@!"
@ 08, 01 say "Cidade ..:" get mde_cid picture "@!"
@ 09, 01 say "Endereco :" get mde_rua picture "@!"
@ 11, 01 say "PARA :"
@ 13, 01 say "Estado ..:" get mpara_uf picture "@!"
@ 14, 01 say "Cidade ..:" get mpara_cid picture "@!"
@ 15, 01 say "Endereco :" get mpara_rua picture "@!"
read
if lastkey() == K_ESC
exit
endif
mde_uf := alltrim( mde_uf ) ; mpara_uf := alltrim( mpara_uf )
mde_cid := alltrim( mde_cid ); mpara_cid := alltrim( mpara_cid )
mde_rua := alltrim( mde_rua ); mpara_rua := alltrim( mpara_rua )
mweb := "https://maps.google.com.br/maps?f=d&source=s_d&saddr="+;
lower(strtran(alltrim(mde_rua)," ","+"))+"+"+;
lower(strtran(alltrim(mde_cid)," ","+"))+"+-+"+;
lower(strtran(alltrim(mde_uf)," ","+"))+;
"&daddr="+lower(strtran(alltrim(mpara_rua)," ","+"))+"+"+;
lower(strtran(alltrim(mpara_cid)," ","+"))+"+-+"+;
lower(strtran(alltrim(mpara_uf)," ","+"))
MyRun( cDirFirefox+" "+mweb, .F. )
enddo
Retu
************************************************************
function MyRun( cComando, lTip )
**************************
local oShell, RET:=0
oShell := win_oleCreateObject( "WScript.Shell" )
if lTip
RET := oShell:Run( "%comspec% /c " + cComando, 0, .T. )
else
oShell:Exec( cComando )
endif
oShell := NIL
return iif( RET = 0, .T., .F. )
Abraços,
Google maps
Enviado: 28 Nov 2013 12:03
por rbonotto
Grande amigo, mais uma vez obrigado !
Funcionando 100%
)