PC Toledo

Código: Selecionar todos

/****************************************
* Compilar: hbmk2 demozip.prg -lhbziparc -lhbmzip -lminizip
****************************************/
PROCEDURE Main()
   LOCAL cTipo := "1"
   LOCAL cDestino:=left("C:\"+CurDir()+spac(100),100)
   LOCAL cOrigem:=left("C:\"+CurDir()+"\*.DBF"+spac(100),100)
   LOCAL cSenha:=SPAC(10)
   LOCAL aArq:={}
   LOCAL c_ExtArq:="bck"  //extensao do arquivo que sera criado

   CLS
   SETMODE(25,80)

   DO WHILE .T.
      @ 5, 1 TO 13, 78
      @ 10,2 SAY REPL("-",76)
      @ 12,3 say REPL(".",74)
      @ 6,23 SAY "(1-Backup/2-Restaura)"
      @ 6, 3 SAY "Tipo............:" GET cTipo VALID (cTipo$[12])
      READ
      IF LASTKEY()=27
       EXIT
      ENDIF
      IF cTipo="2"
       cOrigem:=left("C:\"+CurDir()+"\backup."+c_ExtArq+spac(100),100)
      ENDIF
      @ 7, 3 SAY "Arquivo Origem..:" GET cOrigem PICT "@S56"
      @ 8, 3 SAY "Drive Destino...:" GET cDestino PICT "@S56"
      @ 9, 3 SAY "Senha...........:" GET cSenha PICT "@!"
      READ
      IF LASTKEY()=27
       EXIT
      ENDIF
      IF !FILE(ALLTRIM(cOrigem))
       Alert("Arquivo "+ALLTRIM(cOrigem)+";Nao encontrado!")
       LOOP
      ENDIF
      IF RIGHT(ALLTRIM(cDestino),1)!="\"
       cDest:=ALLTRIM(cDestino)+"\NUL"
       cArqZip:=ALLTRIM(cDestino)+"\backup."+c_ExtArq
      ELSE
       cDest:=ALLTRIM(cDestino)+"NUL"
       cArqZip:=ALLTRIM(cDestino)+"backup."+c_ExtArq
      ENDIF
      IF !FILE(cDest)
       Alert("O Drive "+ALLTRIM(cDestino)+";Nao encontrado!")
       LOOP
      ENDIF
      IF cTipo="1"
       aArq:={}
       IF "*" $ cOrigem
        aDir1 := directory(ALLTRIM(cOrigem))
        vPasta:= LEFT(cOrigem,RAT("\",cOrigem))
        for x=1 to len(aDir1)
         aadd(aArq,vPasta+aDir1[x,1])
        next
       ELSE
         aadd(aArq,ALLTRIM(cOrigem))
       ENDIF
       nTotal:=Len(aArq)

       hb_zipfile( cArqZip,aArq, 9,{|cFile,nPos| eProgresso( cFile, nPos,nTotal) },.t.,ALLTRIM(cSenha),.F.,.F., )

      ELSE
       cDest:=ALLTRIM(cDestino)
       IF RIGHT(ALLTRIM(cDestino),1)!="\"
        cDest+="\"
       ENDIF

       aArq:=hb_GetFilesInZip(ALLTRIM(cOrigem))
       nTotal:=Len(aArq)
       hb_UnzipFile( ALLTRIM(cOrigem),{|cFile,nPos| eProgresso( cFile, nPos,nTotal) },,ALLTRIM(cSenha),cDest,aArq)

      ENDIF
      EXIT
   ENDDO
RETURN

************************************
Function eProgresso(vtxt,xPerc,wTot)
************************************
Local nPre:=(xPerc*100)/wTot,;
      nBar:=(nPre*74)/100
@ 11,3 say "Concluido..: "+str(nPre,3,0)
@ 11,21 say "Arquivo: "+LEFT(vtxt+SPAC(40),44)
@ 12,3 say REPL("X",INT(nBar))
return nil