PC Toledo

Código: Selecionar todos

STATIC FUNCTION win_implib_command_gcc( hbmk, cCommand, cSourceDLL, cTargetLib, cFlags )

   LOCAL nResult

   LOCAL cDef
   LOCAL cSourceDef
   LOCAL hFile
   LOCAL tmp

   LOCAL lDefSource
   LOCAL lNoDefSource := .F.

   SWITCH hb_FNameExt( cSourceDLL )
   CASE ".a"
      /* use these as-is, if specified */
      RETURN win_implib_copy( hbmk, cSourceDLL, cTargetLib )
   CASE ".def"
      /* ugly hack to make it configurable to force skip COFF .lib processing and
         skip to .def lookup, and if that fails, to .def generation */
      cSourceDLL := hb_FNameExtSet( cSourceDLL, ".dll" )
      lDefSource := .T.
      EXIT
   CASE ".nodef"
      cSourceDLL := hb_FNameExtSet( cSourceDLL, ".dll" )
      lNoDefSource := .T.
      /* fall through */
   OTHERWISE
      lDefSource := .F.
      IF ( nResult := win_implib_coff( hbmk, cSourceDLL, cTargetLib ) ) != _HBMK_IMPLIB_NOTFOUND
         RETURN nResult
      ENDIF
   ENDSWITCH

   IF ! lNoDefSource .AND. ;
      ( nResult := win_implib_def( hbmk, cCommand, cSourceDLL, cTargetLib, cFlags ) ) != _HBMK_IMPLIB_NOTFOUND
      RETURN nResult
   ENDIF

   IF lDefSource
      /* Try to generate a .def file from the .dll
         This might help in case the supplied .lib doesn't work. */
      IF win_defgen_command( hbmk, "gendef - {ID}", cSourceDLL, @cDef ) == _HBMK_IMPLIB_OK
         IF ( hFile := hb_vfTempFile( @cSourceDef,,, ".def" ) ) != NIL
            hb_vfWrite( hFile, cDef )
            hb_vfClose( hFile )
            IF ( nResult := win_implib_def( hbmk, cCommand, cSourceDef, cTargetLib, cFlags ) ) != _HBMK_IMPLIB_NOTFOUND
               hb_vfErase( cSourceDef )
               RETURN nResult
            ENDIF
            hb_vfErase( cSourceDef )
         ELSE
            _hbmk_OutErr( hbmk, I_( "Warning: Temporary .def could not be created." ) )
            RETURN nResult
         ENDIF
      ENDIF
   ELSEIF hb_vfExists( tmp := FN_CookLib( cSourceDLL, "lib", ".dll.a" ) )  /* use "lib<dllname>.dll.a" implibs, if there are any */
      cSourceDLL := tmp
   ENDIF

   RETURN win_implib_copy( hbmk, cSourceDLL, cTargetLib )