Em homenagem a Paulo Cesar Toledo
https://pctoledo.org/
É muito amplo isso. Quais são exatamente esses determinados arquivos?porter escreveu:como apagar determinados arquivos
A data anterior a hoje é referente a que: data da última alteração, ou data de criação do arquivo?porter escreveu:com datas anteriores a data de hoje
Não testei, mas acho que FileDate() como outras funções nativas retornam a data de modificação, não de criação.Daniel escreveu:vc pode usar o comando FileDate()
Código: Selecionar todos
Function Main()
Local x, aFiles, cFile, aFileInfo, oFileInfo, dDataHoje:=Date(), cPastaFiles
SET DATE BRIT
SET CENTURY ON
cPastaFiles := "C:\MinhaPasta\MinhaSubPasta\" // coloque aqui o caminho da pasta...
aFiles := Directory( cPastaFiles + "*.TXT" ) // pasta e tipo de arquivo...
For x=1 To Len( aFiles )
Clear Screen
cFile := cPastaFiles + "\" + aFiles[ x, 1 ] // caminho e nome do arquivo...
oFileInfo := FileInfo():new( cFile ) // envia a Classe FileInfo...
?
? "Nome do arquivo............=> ", oFileInfo:fileName
? "Tamanho....................=> ", oFileInfo:fileSize
? "Atributos..................=> ", oFileInfo:fileAttr
?
? "Data da criação............=> ", oFileInfo:createDate
? "Hora da criação............=> ", oFileInfo:createTime
?
? "Data da última alteração...=> ", aFiles[ x, 3 ]
? "Data da última alteração...=> ", aFiles[ x, 4 ]
?
/*
Cuidado. Descomente e/ou altere aqui por sua conta e risco...
*/
If oFileInfo:createDate < dDataHoje
If Alert( "Apagar o arquivo:;;" + cFile + "?;;Pressione ESC para encerrar...", { "Nao", "Sim" } ) = 2
//FErase( cFile )
EndIf
If LastKey() = 27
Return Nil
EndIf
EndIf
Next
Return Nil
/*
CLASS FileInfo
*/
#include "hbclass.ch"
#include "error.ch"
CLASS FileInfo
PROTECTED:
DATA cFileName INIT ""
DATA aInfo INIT { "", 0, CtoD(""), 0, CtoD(""), 0 }
METHOD getInfo
EXPORTED:
METHOD init
ACCESS fileName INLINE ::cFileName
ASSIGN fileName(c) INLINE ::getInfo(c)
ACCESS fileAttr INLINE ::aInfo[1]
ACCESS fileSize INLINE ::aInfo[2]
ACCESS createDate INLINE ::aInfo[3]
ACCESS createTime INLINE TString( ::aInfo[4] )
ACCESS changeDate INLINE ::aInfo[5]
ACCESS changeTime INLINE TString( ::aInfo[6] )
ENDCLASS
METHOD init( cFileName ) CLASS FileInfo
IF Valtype( cFileName ) == "C"
::getInfo( cFileName )
ENDIF
RETURN self
METHOD getInfo( cFileName ) CLASS FileInfo
IF .NOT. File( cFileName )
RETURN ::error( "File not found" , ;
::className(), "getInfo" , EG_ARG, {cFileName} )
ENDIF
::cFileName := cFileName
FileStats( cFileName, @::aInfo[1], ;
@::aInfo[2], ;
@::aInfo[3], ;
@::aInfo[4], ;
@::aInfo[5], ;
@::aInfo[6] )
RETURN selfCódigo: Selecionar todos
USE ATUALIZA // arq. de controle da última execução
IF VLN00 < DATE() // VLN00 = campo date (gravo este campo na saída do sistema)
AEVAL(DIRECTORY("C:\TEMP2\*.DBF"),{|aFile| FErase("C:\TEMP2\"+aFile[1])})
ENDIF
Código: Selecionar todos
USE ATUALIZA // arq. de controle da última execução
REPLACE VLN00 WITH DATE()
CLOSE DATABASE
Código: Selecionar todos
cExtensao := "XML"
CONTADOR := ADIR( "*."+cExtensao )
IF CONTADOR != 0
DECLARE TXT_NOMES[ CONTADOR ]
ADIR( "*."+cExtensao, TXT_NOMES )
FOR CONTADOR := 1 TO LEN( TXT_NOMES )
//
...faço alguma coisa com o arquivo
cFile := TXT_NOMES[CONTADOR]
NEXT
ENDIF
Código: Selecionar todos
FUNCTION ExcluiArq(cArq, cDir)
LOCAL aDir, I
hb_Default(@cArq, "*.*")
hb_Default(@cDir, hb_DirBase()) //pasta onde o executável está rodando por padrão.
aDir := Directory(cArq)
IF Len(aDir) > 0
FOR I:=1 TO Len(aDir)
IF (DTOS(aDir[I,3]) < DTOS(Date()))
fErase(cDir+aDir[I,1])
ENDIF
NEXT
ENDIF
RETURN Nil
Código: Selecionar todos
FUNCTION LimparTemp(cArq, nDias)
LOCAL cFile
hb_Default(@nDias, 10)
cFile := FileSeek(cArq)
DO WHILE !Empty(cFile)
IF FileDate() <= Date() - nDias
IF hb_FileExists(cFile)
FileDelete(cFile)
ENDIF
ENDIF
cFile := FileSeek()
ENDDO
RETURN Nil
Jairo Maia escreveu:A data anterior a hoje é referente a que: data da última alteração, ou data de criação do arquivo?
Todas as funções apresentadas pelos colegas são simples e de fácil entendimento. Porém, optei por usar a Classe FileInfo, que está no exemplo que postei, porque o autor do tópico disse preferir fazer a checagem pela data de CRIAÇÃO do arquivo. Os exemplos dos colegas retornam apenas a data da última alteração.porter escreveu:A data que eu me refiro e a data da geracao do arquivo.txt
Código: Selecionar todos
cFile := cPastaFiles + "\" + aFiles[ x, 1 ] // caminho e nome do arquivo...Código: Selecionar todos
cFile := cPastaFiles + aFiles[ x, 1 ] // caminho e nome do arquivo...Código: Selecionar todos
? "Data da última alteração...=> ", aFiles[ x, 3 ]
? "Data da última alteração...=> ", aFiles[ x, 4 ]Código: Selecionar todos
? "Data da última alteração...=> ", aFiles[ x, 3 ]
? "Hora da última alteração...=> ", aFiles[ x, 4 ]Realmente, as funções ADIR() e Directory() são simples no quesito quantidade de informação e uma classe nova pode trazer mais dados importantes que as padrão não trazem....Porém, optei por usar a Classe FileInfo, que está no exemplo que postei, porque o autor do tópico disse preferir fazer a checagem pela data de CRIAÇÃO do arquivo. Os exemplos dos colegas retornam apenas a data da última alteração.