PC Toledo

Código: Selecionar todos

FUNCTION Envia_email(aFiles,cSubject,cDest,cMsg,cServerIp,cFrom,cUser,cPass,vPORTSMTP,cCC,cBCC,vEMAIL_CONF,wSSL_EMAIL)
   **********************************************************************************************************************
   Local lRet := .f.
   Local oCfg, oError
   Local lAut  := .t.

   TRY
      oCfg := CREATEOBJECT( "CDO.Configuration" )

      WITH OBJECT oCfg:Fields
         :Item( "http://schemas.microsoft.com/cdo/configuration/smtpserver"             ):Value := cServerIp   //server SMTP
         :Item( "http://schemas.microsoft.com/cdo/configuration/smtpserverport"         ):Value := vPORTSMTP
         :Item( "http://schemas.microsoft.com/cdo/configuration/sendusing"              ):Value := 2           // Remote SMTP = 2, local = 1
         :Item( "http://schemas.microsoft.com/cdo/configuration/smtpauthenticate"       ):Value := 1           //
         :Item( "http://schemas.microsoft.com/cdo/configuration/smtpusessl"             ):Value := .f. //wSSL_EMAIL  // .F. Ou .T.
         :Item( "http://schemas.microsoft.com/cdo/configuration/sendusername"           ):Value := AllTrim(cUser)
         :Item( "http://schemas.microsoft.com/cdo/configuration/sendpassword"           ):Value := AllTrim(cPass)
         :Item( "http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout"  ):Value := 60
         :Update()
      END WITH

      lRet := .t.

   CATCH oError
      MsgError( "Não Foi possível Enviar o e-Mail!"  +HB_OsNewLine()+ ;
       "Error: "     + Transform(oError:GenCode,   nil) + ";" +HB_OsNewLine()+ ;
       "SubC: "      + Transform(oError:SubCode,   nil) + ";" +HB_OsNewLine()+ ;
       "OSCode: "    + Transform(oError:OsCode,    nil) + ";" +HB_OsNewLine()+ ;
       "SubSystem: " + Transform(oError:SubSystem, nil) + ";" +HB_OsNewLine()+ ;
       "Mensaje: "   + oError:Description, "Atenção" )

   END

   If lRet
      TRY
         oMsg := CREATEOBJECT ( "CDO.Message" )
         WITH OBJECT oMsg
            :Configuration = oCfg
            :From    = cUser //cFrom
            :Sender  = cUser
            :To      = cDest
            :Subject = cSubject
            :TextBody = cMsg

            For x := 1 To Len( aFiles )
               :AddAttachment(AllTrim(aFiles[x]))
            Next

            :MDNRequested  := .T.               // Requiere respuesta
            :DSNOptions    := 14                //Return a DSN if delivery succeeds, fails, or is delayed.

            //:Fields( "urn:schemas:mailheader:disposition-notification-to" ):Value   := cFrom //'retorno@simplesinformatica.com.br'
            //:Fields( "urn:schemas:mailheader:return-receipt-to" ):Value             := cFrom //'retorno@simplesinformatica.com.br'
            :Fields( "urn:schemas:httpmail:importance" ):Value                      := '2'
            :Fields:update()

            :Send()
         END WITH

         lRet := .t.

      CATCH oError
         msg := 'Não Foi Possível Enviar a Mensagem: "' + cSubject+'"' + CRLF
         msg += 'Verifique se existe conexão com a Internet.' + CRLF
         msg += "Destinatário.: " + cDest                     + CRLF
         msg += "Error.:     "  + Str( oError:GenCode)        + CRLF
         msg += "SubC.:      "  + Str( oError:SubCode )       + CRLF
         msg += "OSCode.:    "  + Str( oError:OsCode )        + CRLF
         msg += "SubSystem.: "  + oError:SubSystem            + CRLF
         msg += "Mensagem.:  "  + oError:Description          + CRLF
         msg += "Operação.: ["  + oError:Operation + "]"      + CRLF

         mArgs := oError:Args
         msg += "Argumento: " + ValType(mArgs) + '[' +Alltrim(Str(Len(mArgs)))+ ']' + CRLF

         If ValType(mArgs) = 'C'
            msg += "Argumento: [" + mArgs + "]"

         ElseIf ValType(mArgs) = 'A'
            For i=1 To Len(mArgs)
               msg += Str(i, 1)+" [" + mArgs[i] + "]" +CRLF
            Next
         Endif

         MsgAtencao( msg )

         lRet := .f.
      END

   Endif

   Return lRet

Código: Selecionar todos

Function PW_EnviaEmail( cPwUser, cPwEmail, cPwNome, cPwPass )
   Local mRetorno := .t.

   //mail Simples nao responda
   cFrom    := "...."
   cTo      := Alltrim(cPwEmail)
   cServerIp:= "...."         //servidor smtp
   cSubject := 'SCP21H - Recuperação de Senha'
   cUser    := '....'
   cPass    := '....'
   vPORTSMTP:= 587 //467
   lConf  	:= .T.
   lSSL  	:= .F.
   aFiles 	:= {} // pode ser uma matriz com vários endereços

   cMsg  	:= 'Simples Informática e Consultoria Ltda'
   cMsg  	+= CRLF + 'SCP21H - Sistema de Contabilidade Pública'+CRLF
   cMsg  	+= CRLF + 'Recuperação de Senha do Usuário:'
   cMsg  	+= CRLF + 'Nome: '     + cPwNome
   cMsg  	+= CRLF + 'Usuário: '  + cPwUser
   cMsg  	+= CRLF + 'Senha: '    + cPwPass
   cMsg  	+= CRLF + 'Email: '    + cPwEmail

   mRetorno := Envia_Email(aFiles, cSubject, cTo, cMsg, cServerIp, cFrom, cUser, cPass, vPORTSMTP, '', '', lCONF, lSSL)

   Return mRetorno

Código: Selecionar todos

https://pctoledo.org/forum/viewtopic.php?f=4&t=10764&start=30
https://pctoledo.org/forum/viewtopic.php?f=2&t=16294&start=15
http://fivewin.com.br/index.php?/topic/26829-erro-ao-enviar-e-mail-via-cdomessage-e-gmail/#comment-278073
https://www.google.com/settings/security/lesssecureapps
https://www.usandoaccess.com.br/tutoriais/enviar-email-usando-o-cdosys.asp