PC Toledo

Código: Selecionar todos

***** prog de testes

#include "minigui.ch"  
#include "hbdyn.ch"
#include "freeimage\FreeImag.ch"
#require "hbfimage"


Function Main()

   HB_GTSYS()

	**** Parametros Basicos cadastro da Empresa ****
	cPIX_KEY := "+5511900000000"  				// chave pix (CNPJ, email, celular)
	cPIX_RECEIVER := "Marcio Martins Moreira" // Nome do Proprietario do PIX
	cPIX_CITY := "Sao Paulo"      				// Nome da Cidade do proprietario do PIX
	cPIX_ZIPCODE := ""

	**** Dados Dinamicos no momentos da Geracao
	nPIX_AMOUNT := 1.25 					// Valor do PIX
	cPIX_DESCRIPTION := "Ped:12345 e demais dados"
	cPIX_IDENTIFICATION := "Identificacao"

	**** Gera String - Testada e OK! ****
	cString = StringPIX ( nPIX_AMOUNT , cPIX_KEY , cPIX_RECEIVER , cPIX_CITY , cPIX_ZIPCODE , cPIX_DESCRIPTION , cPIX_IDENTIFICATION )

	***** ATÉ AQUI, TUDO BEM !!!


	cFile := "arq"
	IF QRCode(cString , cFile+".bmp" )   && Se Gerou arquivo BMP
	

		**** Gera JPG e PNG a partir do BMP (FreeImage) ****
		GeraJPGPNG(cFile)


		**** Mostra o BMP na Tela ****
		ShowQRCode(cFile, cPIX_Description)

	ENDIF
	
	Return Nil








FUNCTION QRcode( cStr, cFile , lFull )
	lFull = iif(type("lFull")="L",lFull,.f.)
   hLib := hb_libLoad( "QRCodeLib.dll" )
	if lFull
	   hb_DynCall( { "FullQRCode", hLib, HB_DYN_CALLCONV_STDCALL  }, .T., .F.,;
			 			RGBCor(255,255,255), RGBCor(0,0,0), cStr, ;
      				3, 1,;
	               5, 5, 200, 200, cFile ) 
	else
	   hb_DynCall( { "FastQRCode", hLib, HB_DYN_CALLCONV_STDCALL}, cStr, cFile )
	endif 
   hb_libFree( hLib )
  	RETURN file(cFile)


FUNCTION RGBCor( nRed, nGreen, nBlue )
	RETURN ( nRed + ( nGreen * 256 ) + ( nBlue * 65536 ) ) 	
  	
  	




Function GeraJPGPNG(cFile)
   fi_Initialise()
   im := fi_Load( FIF_BMP, cFile+".bmp", BMP_DEFAULT )
   nwidthimg   := fi_GetWidth( im )
   nheightimg  := fi_GetHeight( im )
	fi_Save( FIF_PNG, im, cFile+".png", PNG_DEFAULT )
	fi_Save( FIF_JPEG, im, cFile+".jpg", JPEG_DEFAULT )
   fi_DeInitialise()
	Return Nil
  	




Function ShowQRCode (cFile , cPIX_Description)

	DEFINE WINDOW ShowQRCode ;
		AT 0,0 ;
		WIDTH GetDeskTopWidth()/2 ;
		HEIGHT GetDeskTopHeight()/2 ;
		TITLE "PIX:"+cPIX_Description ;
		main ;
		BACKCOLOR {0,0,0} 

	    DEFINE IMAGE Image_1
	        ROW    50
	        COL    50
	        WIDTH  200
	        HEIGHT 200
	        PICTURE cFile+".bmp"
	        VISIBLE .T.
	        STRETCH .t.
		end image

	    DEFINE BUTTON Button_x
	        ROW    50
	        COL    350
	        WIDTH  200
	        HEIGHT 200
	        ACTION ShowQRCode.release
	        FONTNAME "Arial"
	        FONTSIZE 9
	        VISIBLE .t.
	        PICTURE cFile+".bmp"
	    END BUTTON
	END WINDOW

	ShowQRCode.Center
	ShowQRCode.Activate


return Nil






**** GERACAO DE STRING FUNCIONANDO 
**** TESTADO - Marco/2023
function StringPIX()
	parameters nPIX_AMOUNT , cPIX_KEY , cPIX_RECEIVER , cPIX_CITY , cPIX_ZIPCODE , cPIX_DESCRIPTION , cPIX_IDENTIFICATION 

	Private cString
	cString := ""
   cString += get_p_value('00', '01')
   cString += get_p_value('01', '11')
   cString += get_p_account_information(cPIX_KEY, cPIX_DESCRIPTION)
   cString += get_p_value('52', '0000')
   cString += get_p_value('53', '986')
   cString += get_p_value('54', alltrim(str(nPIX_AMOUNT)))
   cString += get_p_value('58', 'BR')
   cString += get_p_value('59', cPIX_RECEIVER)
   cString += get_p_value('60', cPIX_CITY)
   ** cString += get_p_value('61', '')
   cString += get_p_additional_data_field(cPIX_IDENTIFICATION)
   cString += "6304"
   cString += hb_numtohex(hb_crcct(cString, 0xFFFF, 0x11021))
	return cString
   

function get_p_value(identify, value)
	return trim(identify + strzero(len(alltrim(value)), 2) + value)

function get_p_account_information(key, description)
   Local base_pix := get_p_value('00', 'br.gov.bcb.pix')
   Local info_string := ''
   info_string += get_p_value('01', key)
   info_string += get_p_value('02', description)
   return get_p_value('26', base_pix + info_string)


function get_p_additional_data_field(identification)
	if identification != Nil
		return get_p_value('62', get_p_value('05', identification))
	else
		return get_p_value('62', get_p_value('05', '***'))
	endif
	return

Código: Selecionar todos

Function Main()

   HB_GTSYS()

Código: Selecionar todos

REQUEST HB_GT_WVG_DEFAULT
 REQUEST HB_GT_WVG