Código: Selecionar todos
/*
PINFOJPA - SOBRE O JPA
2012 José Quintas
*/
#include "hbgtinfo.ch"
#include "hbmemory.ch"
FUNCTION pInfoJPA()
LOCAL cText := "", cExeName, nThreads := 0
cExeName := Upper( hb_FNameName( hb_ProgName() ) ) + ".EXE"
cText += cExeName + ": " + AppVersaoExe() + hb_eol()
cText += "Base de Dados: " + Transform( Str( AppVersaoSQL() * 100, 10 ), "@R 9999.99.99.99" ) + hb_eol()
cText += "Hardware: " + DriveSerial() + hb_eol()
cText += Version() + hb_eol()
cText += HB_Compiler() + hb_eol()
cText += "Memory: " + LTrim( Transform( Memory(0) / 1024 / 1024, "999.99" ) ) + " GB" + hb_eol()
cText += "VM Memory: " + LTrim( Transform( Memory( HB_MEM_VM ) / 1024 / 1024, "999.99" ) ) + " GB" + hb_eol()
cText += "Window Size (Row/Col): " + LTrim( Str( MaxRow() + 1 ) ) + " x " + LTrim( Str( MaxCol() + 1 ) ) + hb_eol()
cText += "Window Size (Pixels): " + Ltrim( Str( hb_gtInfo( HB_GTI_SCREENWIDTH ) ) ) + " x " + ;
Ltrim( Str( hb_gtInfo( HB_GTI_SCREENHEIGHT ) ) ) + hb_Eol()
IF HB_GtInfo( HB_GTI_FONTNAME ) != NIL
cText += "Font Name: " + HB_GTINFO( HB_GTI_FONTNAME ) + hb_eol()
cText += "Font Size: " + LTrim(Str( HB_GTINFO( HB_GTI_FONTSIZE ) ) ) + " x " + LTrim( Str( HB_GTINFO( HB_GTI_FONTWIDTH ) ) ) + " x " + LTrim( Str( HB_GTINFO( HB_GTI_FONTWEIGHT ) ) ) + hb_eol()
ENDIF
cText += "Temp Path: " + AppTempPath() + hb_eol()
cText += "Terminal Server Client: " + iif( win_OsIsTsClient(), "Yes", "No" ) + hb_eol()
__vmCountThreads( @nThreads, 0 )
cText += "Threads running " + Ltrim( Str( nThreads, 10 ) ) + hb_Eol()
cText += "GT: " + hb_gtInfo( HB_GTI_VERSION ) + hb_Eol()
cText += "OS: " + iif( hb_osIs64bit(), "64", "32" ) + " bits" + hb_Eol()
MsgExclamation( cText )
RETURN NIL
Talvez não todas as GTs, mas não sei se precisa misturar porque à primeira vista são parecidas.
uma cria janela bloqueando as demais (MODAL), e outra não.
Nem todas GTs aceitam multithread.
Basicamente, compilando com -GUI vai usar a GT gráfica default do ambiente.
hb_gtinfo( HB_GTI_VERSION ) vai retornar o nome da GT em uso.
Não sei direito quais os nomes disponíveis, alguns são: GTWIN, GTWVT, GTWVG, GTWVW
GTGUI é a forçada em programas GUI, como hwgui, minigui, etc. pra não ter janela console.