BOLETOS? Não tem problemas, estas ferramentas vão te ajudar

[asimoes]

Abel,

Você sabe me dizer quando será o fim da emissão de boleto sem registro, porque eu tenho um sistema que fiz pro nosso condomínio, e não faço remessa, eu só baixo o arquivo retorno para saber quem pagou, isso no banco itaú

[JoséQuintas]

É proibido postar fontes do Mr.Boleto.
Já fui avisado pelo autor, quando postei aqui algumas modificações.

[Abel]

O fim dos boletos pela febraban é 31/12/2016.

mas os bancos já começaram a restringir o uso do boleto sem registro.
no meu caso BB, tenho ate final do mês 07 para usar com registro, se utilizar sem registro a taxa será de 100%, ou seja, quase 9.00 cada boleto pago pelo cliente sem registro será descontado da minha conta.

Não é o fim, os bancos é que querem o fim. Pela febraban, os boletos sem registros em 2017 poderão ser pagos apenas no banco origem do boleto.

ou seja, boleto do itau sem registro, so pode pagar pelo itau.

Abel

[rubens]

Bom dia...

Quintas, como é que a história do MR.Boleto?
Não pode postar fontes dele aqui?
Então se eu usar ele e precisar e alguma ajuda somente com o desenvolvedor?
Estou partindo para implementar isso e ia partiar para o mrboleto... mas agora é pensar de novo isso..

Rubens

[rochinha]

Amiguinhos,

De um certo modo o autor dará o suporte. Se a ferramenta foi disponibilizada de forma livre, provavelmente ele faça as alterações solicitadas e poste no local onde disponibilizou com intuito de centralizar, unificar e não permitir várias versões fora do controle.

Veja, o gerenciador de controle, permite o usuário fazer parte da vida do software e contribuir com suas melhorias. O código sempre vai estar lá, mas se não houver manutenção nem comunicação do autor, não permitir apresentar o código a comunidade para que as várias cabeças possam dar luz e radical.

A idéia também é evitar espertinhos de ganhar uma moeda, sem dar crédito ao menos, em cima do suor alheio.

Lógico que tal restrição não impede o uso da ferramenta, basta instalar um servidor de versões e compartilhar com a comunidade.

[rubens]

Boa tarde...

Alguém tá gerando Boletos pra o Sicredi com o MRBOLETO ?
Eu consegui compilar a classe no meu sistema, gero os arquivos exemplos certinho...
Daí peguei um Boleto do sicredi que já gero por aqui pelo site deles, consegui colocar todas as informações mas a linha digitável não.
Fui no site e digitei a linha que foi gerada com o MRBOLETO e dá erro de digitos verificadores.
O resto do boleto tá igualzinho... carteira, nosso número ...

Linha do Sicredi:
74891.11612.00179.808068.14590.331089 7 69590000035200

Linha do MR Boleto.
74891.59033 31600.179803 80659.033106 1 69560000035200

Daí empacou...

Obrigado
Rubens

[fladimir]

Rubens desculpe a pergunta, seria para projeto novo? Se sim como usa o ACBr já tem pronto nele talvez seria mais rápido

Qto ao MRBoleto tem pessoal q usa tb, mas não saberia te ajudar.

[rubens]

Então Fladimir...

Eu queria colocar o MRBOLETO para funcionar aqui... parece ser bem simples, rápido e não dependeria de ferramenta externa...
Mas se não conseguir... vou partir pro ACBR já cheguei a gerar uns boletos teste nele mas não coloquei para frente...

De qualquer forma se não conseguir no MRBoleto com certeza vou pro ACBR sim e aceito ajuda sim... kkkkk

Obrigado
Rubens

[pena]

boa tarde, onde consigo os fontes destes exemplos?

[JoséQuintas]

O Mr Boleto funciona bem, acabei usando pra determinada situação.
Fiz alterações pra ficar mais fácil de usar.
Mas quando postei aqui, o autor pediu pra remover os fontes, porque o tipo de licença não permitia isso
Por uma grande coincidência, há exatos dois anos atrás.

https://pctoledo.org/forum/viewto ... eto#p91990

[asimoes]

Olá Pessoal,

Alguém tem rotina para geração de arquivo remessa para o Itaú?

O Itaú já está nos informando sobre o registro da cobrança.

[JoséQuintas]

Isso muda um pouco conforme a carteira de cobrança.
E como estão alterando, convém até usar um manual novo.

Tem um manual do Itaú com várias carteiras de cobrança, criei só a que eu precisava.
Mesmo assim, no ano passado criei outra geração, também do Itaú, que não fazia parte desse manual.
E não sei se essas mudanças novas incluem alteração de layout.
Então é melhor confirmar no banco, ter certeza qual é a carteira, e qual é o layout pra ela.

[asimoes]

Quintas,

A nossa carteira é a 109

[JoséQuintas]

Como o fonte segue a sequência do manual, fácil de confirmar no manual.

Código: Selecionar todos

STATIC FUNCTION TxtItau( mTipoReg )
   MEMVAR mTxtDocto, mValor, mCnpj
   MEMVAR mAgencia, mConta, mCarteira, mQtRegs, mDocBanco, mTxJuros, mnfNotFis, mTaxaBoleto

mTxtDocto := mnfNotFis
IF ! Empty( jpfinan->fiParcela )
   mTxtDocto := mTxtDocto + "/" + jpfinan->fiParcela
ENDIF

SET ALTERNATE ON
SET CONSOLE OFF

DO CASE
CASE mTipoReg == "I" // Inicial
   ?? "0"
   ?? "1"
   ?? "REMESSA"
   ?? "01"
   ?? Pad("COBRANCA",15)
   ?? mAgencia
   ?? "00"
   ?? Substr( mConta, 1, Len( mConta ) - 1 )
   ?? Substr( mConta, Len( mConta ), 1 )
   ?? Space( 8 )
   ?? Pad( AppEmpresaNome(), 30 )
   ?? "341"
   ?? Pad( "BANCO ITAU S/A", 15 )
   ?? StrZero( Day( Date() ), 2 ) + StrZero( Month( Date() ), 2 ) + StrZero( Year( Date() ) - 2000, 2 )
   ?? Space(294)
   ?? StrZero( mQtRegs, 6 )
   ?
CASE mTipoReg == "F" // Final
   ?? "9"
   ?? Space(393)
   ?? StrZero( mQtRegs, 6 )
   ?
CASE mTipoReg == "D"
   mValor := jpfinan->fiValor + mTaxaBoleto
   ?? "1"
   IF Val( jpfinan->fiSacado ) == 0 .OR. jpfinan->fiSacado == jpfinan->fiCliFor
      ?? "02" // 04=CNPJ EMPRESA
      ?? StrZero( Val( SoNumeros( jpempre->emCnpj ) ), 14 )
   ELSE
      Encontra( jpfinan->fiCliFor, "jpcadas", "numlan" )
      IF Len( SoNumeros( jpcadas->cdCnpj ) ) == 14
         ?? "04" // 04=CNPJ TERCEIRO
      ELSE
         ?? "03"
      ENDIF
      ?? Pad( SoNumeros( jpcadas->cdCnpj ), 14 )
   ENDIF
   ?? mAgencia
   ?? "00"
   ?? Substr( mConta, 1, Len( mConta ) - 1 )
   ?? Substr( mConta, Len( mConta ), 1 )
   ?? Space(4)
   ?? Space(4) // Nota 27
   ?? Pad( jpfinan->fiDocAux, 25 )
   // ?? Space(25) // Titulo na empresa
   IF mCarteira == "112"
      ?? Space(8) // Escritural, o Itau vai preencher
   ELSE
      ?? StrZero( Val( mDocBanco ), 8 ) // Direta, sequencial
   ENDIF
   ?? StrZero( 0, 13 ) // Outra moeda
   ?? mCarteira // "109" ou "112"
   ?? Space(21)
   ?? "I" // Nota 5
   ?? "01" // Remessa - Nota 6
   IF jpfinan->fiCliFor == jpfinan->fiSacado
      IF "CARREFOUR" $ jpcadas->cdNome .OR. "ELDORADO S/A" $ jpcadas->cdNome
         IF "/" $ mTxtDocto
            mTxtDocto := Substr( mTxtDocto, 1, At( "/", mTxtDocto ) - 1 )
            mTxtDocto := StrZero( Val( mTxtDocto ), 9 ) + " "
         ENDIF
         ?? mTxtDocto
      ELSE
         ?? Right( mTxtDocto, 10 ) // Nota 18
      ENDIF
   ELSE
      ?? Pad( jpfinan->fiDocAux, 10 )
   ENDIF
   ?? StrZero( Day( jpfinan->fiDatVen ), 2 ) + StrZero( Month( jpfinan->fiDatVen ), 2 ) + StrZero( Year( jpfinan->fiDatVen ) - 2000, 2 )
   ?? StrZero( mValor * 100, 13 )
   ?? "341"
   ?? StrZero( 0, 5 ) // Nota 9 - Agencia cobradora
// Alterado em 14-12-2011 pra todos, pra permitir protestar
//   IF "CORDEIRO" $ AppEmpresaApelido() .OR. "CARBOLUB" $ AppEmpresaApelido() .OR. "MARINGA" $ AppEmpresaApelido()
      ?? "01" // Cordeiro - Duplicata Mercantil
//   ELSE
//      ?? "99" // Especie de Docto Diversos - Nota 10
//   ENDIF
   ?? "N"  // Aceite
   ?? StrZero( Day( jpfinan->fiDatEmi ), 2 ) + StrZero( Month( jpfinan->fiDatEmi ), 2 ) + StrZero( Year( jpfinan->fiDatEmi ) - 2000, 2 )
   IF ( "CORDEIRO" $ AppEmpresaApelido() .OR. "CARBOLUB" $ AppEmpresaApelido() ) .AND. jpfinan->fiCliFor == jpfinan->fiSacado
      ?? "43" // SUJEITO A PROTESTO SE NÃO FOR PAGO NO VENCIMENTO
   ELSE
      ?? "  " // Instrucao Nota 11 - mensagens
   ENDIF
   ?? "  " // Instrucao Nota 11 - mensagens
   ?? StrZero( mValor * mTxJuros / 30, 13 )
   ?? "      " // Data limite pra desconto
   ?? StrZero( 0, 13 ) // Desconto a ser concedido - nota 13
   ?? StrZero( 0, 13 ) // IOF recolhido - nota 14
   ?? StrZero( 0, 13 ) // Abatimento concedido - nota 13
   IF Val( jpfinan->fiSacado ) == 0
      Encontra( jpfinan->fiClifor, "jpcadas", "numlan" )
   ELSE
      Encontra( jpfinan->fiSacado, "jpcadas", "numlan" )
   ENDIF
   mCnpj := SoNumeros( jpcadas->cdCnpj )
   IF Len( mCnpj ) <= 11
      ?? "01"
   ELSE
      ?? "02" // 01=CPF 02=CNPJ
   ENDIF
   ?? StrZero( Val( mCnpj ), 14 )
   ?? Pad( jpcadas->cdNome, 30 )
   ?? Space(10) // Nota 15
   ?? Pad( Trim( jpcadas->cdEndCob ) + " " + Trim( jpcadas->cdNumCob ) + " " + Trim( jpcadas->cdComCob ), 40 )
   ?? Pad( jpcadas->cdBaiCob, 12 )
   ?? StrZero( Val( SoNumeros( jpcadas->cdCepCob ) ), 8 )
   ?? Pad( jpcadas->cdCidCob, 15 )
   ?? jpcadas->cdUfCob
   Encontra( jpfinan->fiCliFor, "jpcadas", "numlan" )
   IF jpfinan->fiCliFor == jpfinan->fiSacado
      ?? Space(30)
   ELSE
      ?? Pad( jpcadas->cdNome, 30 )
   ENDIF
   ?? Space(4)
   ?? StrZero( Day( jpfinan->fiDatVen ), 2 ) + StrZero( Month( jpfinan->fiDatVen ), 2 ) + StrZero( Year( jpfinan->fiDatVen ) - 2000, 2 ) // Data de mora
   ?? StrZero( 0, 2 ) // Qtd.Dias - nota 11
   ?? Space(1)
   ?? StrZero( mQtRegs, 6 )
   ?

   // Mensagens adicionais

//   mQtRegs += 1
//   ?? "5"
//   ?? Space(350)
//   ?? Pad( "Apos vencto, www.itau.com.br/boletos", 40 ) // maximo 40
//   ?? Space(3)
//   ?? StrZero( mQtRegs, 6 )
//   ?

ENDCASE
mQtRegs += 1
SET ALTERNATE OFF
SET CONSOLE ON

RETURN NIL

[JoséQuintas]

Talvez mais interessante se deixasse igual fiz no Bradesco.

Código: Selecionar todos

   IF ::cBancoNumero == "237"
      IF Len( ::Cnab400 ) == 0
         ::Cnab400 := { "", "" }
         //----- registro inicial ---
         /*     */ cTxt := ""
         /* 001 */ cTxt += "0"                                // Fixo: 0=Registro inicial
         /* 002 */ cTxt += "1"                                // Fixo: ID Remessa
         /* 003 */ cTxt += "REMESSA"                          // Fixo: Decricao
         /* 010 */ cTxt += "01"                               // Fixo: Codigo de Servico
         /* 012 */ cTxt += Pad( "COBRANCA", 15 )              // Fixo: Literal Servico
         /* 027 */ cTxt += Padl( ::cBancoIDBeneficiario, 20, "0" )  // Codigo da empresa no Bradesco
         /* 047 */ cTxt += Pad( ::acBeneficiario[ 2 ], 30 )   // Nome da empresa
         /* 077 */ cTxt += ::cBancoNumero                     // Fixo: Codigo do Banco
         /* 080 */ cTxt += Pad( "BRADESCO", 15 )              // Fixo: Nome do Banco
         /* 095 */ cTxt += StrZero( Day( Date() ), 2 ) + StrZero( Month( Date() ), 2 ) + Right( StrZero( Year( Date() ), 4 ), 2 ) // Data da gravacao Dia/Mes/Ano, 2 digitos de cada
         /* 101 */ cTxt += Space(8)                           // Espacos
         /* 109 */ cTxt += "MX"                               // MX - olhar pag. 16, não tem nada
         /* 111 */ cTxt += StrZero( ::nSequencial, 7 )        // Num. sequencial de remessa - olhar pag. 16 // nao pode pular, reiniciar ou zerar
         /* 118 */ cTxt += Space(277)                         // Espacos
         /* 395 */ cTxt += StrZero( 1, 6 )                    // Num. sequencial de registro
         ::cnab400[ 1 ] := cTxt
      ENDIF