Alguém tem um exemplo de Harbour modo texto com mouse?

[JoséQuintas]

O que usei numa época foi o teclado virtual do Windows: osk.exe

[cjp]

Nossa, que maravilha, não sabia que isso existia. Sem dúvida já resolve meu problema.

Mas agora, mais por curiosidade, questiono: não é possível simular uso do ESC e do ENTER com o mouse em Harbour?

[microvolution]

Olá CJP pra mim é um prazer poder lhe oferecer alguma ajuda, que tenho aprendido aqui...
Se entendi bem, o próprio harbour já oferece esse recurso automático do MOUSE nos GETs...
O JQuintas, tem muito me ajudado!
Qualquer coisa lhe passo os códigos que uso para que o clipper/harbour funcione os botões dentro dos GETs, pois isso é uma das coisas NATIVAS de nossa nova linguagem!
Abraços!

[cjp]

Se vc puder passar o código, fico grato.

O mouse já estou usando. Só não consegui ainda usar ESC e ENTER com o mouse.

[JoséQuintas]

Outra coisa que uso aqui, mas vale pro MOUSE não pro CELULAR, é usar o botão contrário do mouse como ESC.
Pode também colocar algum lugar pra clicar, tipo um botões SALVAR e CANCELAR.

E se está usando GTWVG, o (X) da janela pode equivaler a ESC.

Geralmente acesso meu computador pelo celular, mas usando o remoto da Microsoft. Nele aparecem todas as teclas.

[GilmarDalantonia]

Bom dia Galera... aproveitando o tópico... não estou conseguindo mudar o cursor dentro do tbrowse com o mouse, o foco ta na primeira linha e qdo clico em outra lina ou outra coluna não muda... alguem pode me ajudar.

[lugab]

Bom dia a todos..

Pessoal, como seria a rotina de chamada desse teclado virtual (osk.exe) citado pelo QUINTAS, durante um get/read ?

[JoséQuintas]

não estou conseguindo mudar o cursor dentro do tbrowse com o mouse,

Também depende de testar o click do mouse, e mover linha/coluna.
No meu tbrowse uso rotinas que peguei não lembro de onde, acho que foi superlib.

https://github.com/JoseQuintas/JoseQuin ... browse.prg

como seria a rotina de chamada desse teclado virtual (osk.exe)

Não sei porque, mas no Windows 10 isso deixou de funcionar, o Windows não aceita mais chamar o osk.exe pelo aplicativo.

[elaineosm]

Olá, boa tarde a todos!
baixei o exemplo postado "ESCOLA" e tentei compliar mas dá o seguinte erro no arquivo ze_prompt
"sintax error at 'STATIC'"

A linha é
THREAD STATIC aRatOpcoes := {}

Alguém pode me auxiliar?
obg

[JoséQuintas]

Se o problema for THREAD, compile usando -mt, ou retire a palavra.
Isso é pra cada thread ter sua própria variável estática, que só faz diferença em multithread.

[elaineosm]

Obg. agora compila, mas o mouse não está funcionando. Meu SO é o Windows 10. Será q isso pode ter alguma coisa a ver?

[JoséQuintas]

Testei aqui no Windows 10.
As alterações pra mouse foram parciais, funciona no menu vertical e no tbrowse.

[elaineosm]

estranho. No meu não funciona

[JoséQuintas]

Nem vi que tinha HBP na pasta, funcionou com e sem ele

hbmk2 *.prg

hbmk2 *.hbp

Dos dois modos funcionou normal.
A única diferença é que de um jeito gerou alunos.exe e do outro jeito gerou escolar10.exe

Difícil, mas não impossível: aqui usei Harbour 3.4

Sem checagem -w3 -es2 não dá pra saber se faltou alguma declaração adicional que poderia ser diferente no 3.2.
Aliás... não aceitar o THREAD foi estranho.
Qual Harbour usa aí? ou XHarbour?

Pode ser interessante descobrir o porque não funcionou.

[Anilto]

O código abaixo compila no harbour 3.2 com windows 10, porém não assume o mouse do windows:

Código: Selecionar todos

#include "inkey.ch"

Function Main()

	SET EVENTMASK TO HB_INKEY_ALL

	While LastKey() != K_ESC

		Clear Screen
		DispBox( 0, 1, 2, MaxCol(), Nil, "GR+/N" )
		DispBox( 3, 1, MaxRow(), MaxCol(), Nil, "G+/N" )

		@ 1,3  PROMPT "Finalizar"
		@ 1,16 PROMPT "Ag.financeira"
		@ 1,32 PROMPT "Contas bancárias"
		@ 1,52 PROMPT "Telefones"
		@ 1,66 PROMPT "Compromissos"

		MENU TO OPC

		If MRow() != 1
			Loop
		ElseIf LastKey() != K_ESC
			Alert( "Você clicou na opção: " + Hb_NToS( opc ) )
			InKey(5)
		EndIf

	EndDo

Return Nil

Agora, acrescentando um REQUEST HB_GT_WVT_DEFAULT, aceita o mouse no windows 10:

Código: Selecionar todos

#include "inkey.ch"
REQUEST HB_GT_WVT_DEFAULT

Function Main()

	SET EVENTMASK TO HB_INKEY_ALL

	While LastKey() != K_ESC

		Clear Screen
		DispBox( 0, 1, 2, MaxCol(), Nil, "GR+/N" )
		DispBox( 3, 1, MaxRow(), MaxCol(), Nil, "G+/N" )

		@ 1,3  PROMPT "Finalizar"
		@ 1,16 PROMPT "Ag.financeira"
		@ 1,32 PROMPT "Contas bancárias"
		@ 1,52 PROMPT "Telefones"
		@ 1,66 PROMPT "Compromissos"

		MENU TO OPC

		If MRow() != 1
			Loop
		ElseIf LastKey() != K_ESC
			Alert( "Você clicou na opção: " + Hb_NToS( opc ) )
			InKey(5)
		EndIf

	EndDo

Return Nil

E por fim, acrescentando as opções de HBInfo dá para ajustar as acentuações e localização:

Código: Selecionar todos

#include "inkey.ch"
/* HBGTInfo para maior controle do console */
#include "hbgtinfo.ch"
/* Mudando o padrão WIN (console antigo) para WVT (console após o Windows Vista - acho) */
REQUEST HB_GT_WVT_DEFAULT
/* Os REQUEST abaixo servem para carregar os detalhes da lingagem e página de códigos */
REQUEST HB_LANG_PT
REQUEST HB_CODEPAGE_UTF8

Function Main()

	/* Chamando a linguagem previamente requisitada e a página de códigos */
	HB_LANGSELECT('PT')
	HB_CDPSELECT('UTF8')
	/* Opções de HBGTInfo */
	HB_GtInfo( HB_GTI_MAXIMIZED, .F. )
	HB_GtInfo( HB_GTI_FONTNAME, "Lucida Console" )
	HB_GtInfo( HB_GTI_WINTITLE, "Teste para Mouse" )
	/* Fim de opções de HBGTInfo */
	
	SET EVENTMASK TO HB_INKEY_ALL

	While LastKey() != K_ESC

		Clear Screen
		DispBox( 0, 1, 2, MaxCol(), Nil, "GR+/N" )
		DispBox( 3, 1, MaxRow(), MaxCol(), Nil, "G+/N" )

		@ 1,3  PROMPT "Finalizar"
		@ 1,16 PROMPT "Ag.financeira"
		@ 1,32 PROMPT "Contas bancárias"
		@ 1,52 PROMPT "Telefones"
		@ 1,66 PROMPT "Compromissos"

		MENU TO OPC

		If MRow() != 1
			Loop
		ElseIf LastKey() != K_ESC
			Alert( "Você clicou na opção: " + Hb_NToS( opc ) )
			InKey(5)
		EndIf

	EndDo

Return Nil

O Harbour funciona em pelo menos três contextos HB_GT:
1. HB_GT_WIN, que trabalha com os padrões do console (CMD) tipo DOS e Windows até XP);
2. HB_GT_WVT, que trabalha com os consoles (CMD) dos WIndows modernos;
3. HB_GT_GUI, para interfaces gráficas tipo janelas.
Por padrão, se não usar REQUEST HB_GT_xxx, o compilador carrega o contexto HB_GT_WIN, por isso há problemas com mouse nos Windows modernos.