Qual lib usar para configurar fontes

porter · Mensagem por **porter** » 28 Fev 2018 17:53

Olá pessoal,
Estou compilando com o GTWVG, estive olhando alguns exemplos do Giovanni Di Maria, tem alguns exemplos que quero adaptar ao sistema, mas em algumas partes do sistema, estou usando o SETMODE(43, 80), mas com GTWVG não está dando certo, qual lib poderia usar para poder resolver a questão sobre o tamanhos dos fontes.
Com os comandos abaixo, com GTWVG, não funciona

Código: Selecionar todos

SETMODE(43, 80)
@ 01,00 CLEAR TO 43,79   
@ 01,01 SAY "   Codigo: "  GET codigo pict "99999"
@ 02,01 SAY "Descrição:"  GET descricao pict "@!"
@ 03,01 SAY "    Compl:"   GET complemento pict "@!"
@ 04,01 SAY "      CST:"     GET cst pict "9999999999"
@ 05,01 SAY "      NCM:"    GET ncm pict "99999999"
@ 06,01 SAY "     CFOP:"   GET cfop pict "9999"

HARBOUR 3.2.0(dev)
GTWVG

Mensagem por **JoséQuintas** » 28 Fev 2018 21:16

Traduza o "não funciona".

porter · Mensagem por **porter** » 01 Mar 2018 08:48

Olá Quintas,
Com GTWVG, o SETMODE(43,80), não muda a apresentação do vídeo, por exemplo, no comando
@30,10 SAY "Nome :", não aparece.

Código: Selecionar todos

SETMODE(43, 80)
2	@ 01,00 CLEAR TO 43,79   
3	@ 01,01 SAY "   Codigo: "  GET codigo pict "99999"
4	@ 02,01 SAY "Descrição:"  GET descricao pict "@!"
5	@ 03,01 SAY "    Compl:"   GET complemento pict "@!"
6	@ 04,01 SAY "      CST:"     GET cst pict "9999999999"
7	@ 05,01 SAY "      NCM:"    GET ncm pict "99999999"
8	@ 06,01 SAY "     CFOP:"   GET cfop pict "9999"
9	@ 30,10 SAY "Nome     :"  GET nome pict "@!" // essa linha não aparece no vídeo por ser linha 30

HARBOUR 3.2.0(dev)
GTWVG

Mensagem por **JoséQuintas** » 01 Mar 2018 10:13

Código: Selecionar todos

#include "inkey.ch"

PROCEDURE Main

   LOCAL codigo := 1, descricao := SPace(30), complemento := Space(30)
   LOCAL CST := 0, ncm := 0, cfop := 0, nome := Space(30)
SETMODE(43, 80)
@ 01,00 CLEAR TO 43,79
@ 01,01 SAY " Codigo: " GET codigo pict "99999"
@ 02,01 SAY "Descrição:" GET descricao pict "@!"
@ 03,01 SAY "  Compl:" GET complemento pict "@!"
@ 04,01 SAY "   CST:"  GET cst pict "9999999999"
@ 05,01 SAY "   NCM:"  GET ncm pict "99999999"
@ 06,01 SAY "  CFOP:" GET cfop pict "9999"
@ 30,10 SAY "Nome  :" GET nome pict "@!" // essa linha não aparece no vídeo por ser linha 30
READ
   RETURN

PROCEDURE HB_GTSYS

   REQUEST HB_GT_WVG_DEFAULT
   RETURN

hbmk2 test GTWVG.hbc -w0 -es0

Mensagem por **JoséQuintas** » 01 Mar 2018 10:15

Apenas comentário, não sei se foi isso que aconteceu:

Caso não force a GTWVG como default, acaba entrando console.

Uma opção é usando GTWVG.HBC e outra usando aquele hb_gtsys que possui o gt default.

porter · Mensagem por **porter** » 01 Mar 2018 18:44

Para o sistema ficar em tela cheia, a FUNCTION ExpandirTela, está funcionando perfeitamente, em contra partida não consigo
com o SETMODE(43,80) fazer com que o comando @ 30,01 SAY "Nome:" GET nome pict "@!" apareça, pelo fato de estar
na linha 30 (trinta), só está dando certo se não Expandir a Tela.

Código: Selecionar todos

#include "inkey.ch"
PROCEDURE Main
    LOCAL codigo := 1, descricao := SPace(30), complemento := Space(30)
    LOCAL CST := 0, ncm := 0, cfop := 0, nome := Space(30)
*   ExpandirTela()
    SETMODE(43, 80)
    @ 01,00 CLEAR TO 43,79
    @ 01,01 SAY "   Codigo:" GET codigo      pict "99999"
    @ 02,01 SAY "Descricao:" GET descricao   pict "@!"
    @ 03,01 SAY "    Compl:" GET complemento pict "@!"
    @ 04,01 SAY "      CST:" GET cst         pict "9999999999"
    @ 05,01 SAY "      NCM:" GET ncm         pict "99999999"
    @ 06,01 SAY "     CFOP:" GET cfop        pict "9999"
    @ 30,01 SAY "     Nome:" GET nome        pict "@!" // essa linha não aparece no vídeo por ser linha 30
    READ
    RETURN
  	 
PROCEDURE HB_GTSYS
    REQUEST HB_GT_WVG_DEFAULT
    RETURN
	
FUNCTION ExpandirTela
    SETMODE(25, 80)
    HB_GtInfo( HB_GTI_RESIZABLE, .F. )
    screenWidth := HB_GTINFO( HB_GTI_DESKTOPWIDTH )
    screenHeight:= HB_GTINFO( HB_GTI_DESKTOPHEIGHT )
    wvt_SetFont( "courier new"   , Round(( screenHeight / MaxRow() ),0)-4, Round(( screenWidth / MaxCol() ),0), 0 )
    WVT_MAXIMIZE()
    RETURN

Mensagem por **JoséQuintas** » 01 Mar 2018 21:17

pelo fato de estar na linha 30 (trinta), só está dando certo se não Expandir a Tela.

Tá falando sério?
Não seria por causa disto?

FUNCTION ExpandirTela
SETMODE(25, 80)

porter · Mensagem por **porter** » 02 Mar 2018 19:17

Se na tela principal do sistema, configurar como SETMODE(25, 80), essa rotina com SETMODE(43,80) não terá
efeito, a linha 30 não aparece, só da certo se configurar desde a tela principal SETMODE(43,80).

Mensagem por **JoséQuintas** » 02 Mar 2018 19:51

A GTWVG ajusta automático o tamanho do fonte para o maior que der, pra preencher a tela, ao maximizar.
Se quer trabalhar com 43 linhas, é SetMode( 43, 80 )
Se configurar o tamanho do fonte pra 25 X 80, ao alterar pra 43x80 a GTWVG vai reduzir o tamanho do fonte pra caberem 43 linhas.
Não estou entendendo o que está querendo fazer.

Se quer manter a proporção da tela DOS/Console, as opções são 24 linhas, 28 linhas ou 33 linhas.
Acima disso as linhas acabam ficando grudadas, com pouco espaço entre as linhas.

Só lembrando... a intenção do Windows 10 é não ter mais janelas, igual acontece em telefone celular.
não sei se a sua intenção é trabalhar com janelas de tamanho diferente no aplicativo.

Mensagem por **asimoes** » 02 Mar 2018 19:57

Vou chutar, rs, não testei

Código: Selecionar todos

SETMODE(25,80)
hb_gtReload( "WVG" )

Mensagem por **asimoes** » 02 Mar 2018 20:00

Eu faço assim:

Código: Selecionar todos

   Hb_gtReload( "WVG" )
   
   SetMode( 27, 80 )
   
   CLS
   
   SetColor( "W+/B" )
   
   Hb_gtInfo( HB_GTI_CLOSEMODE, 0 )
   
   Hb_gtInfo( HB_GTI_FONTNAME, "Lucida Console" )
   
   Hb_gtInfo( HB_GTI_WINTITLE, cTitulo )
   
   Hb_gtInfo( HB_GTI_COMPATBUFFER, .T. ) 
   
   Hb_gtInfo( HB_GTI_ICONFILE, "AVI\ASAPREV.ICO" )
    
   Hb_gtInfo( HB_GTI_MAXIMIZED, .T. )
  
   Hb_gtInfo( HB_GTI_SPEC, HB_GTS_WNDSTATE, HB_GTS_WS_MAXIMIZED )

porter · Mensagem por **porter** » 03 Mar 2018 11:36

No GTWVT, consigo maximizar totalmente a tela e alternar entre 25 X 80 e 43 X 80.
Já no GTWVG, houve um progresso, estava faltando acrescentar a linha Hb_gtReload( "WVG" ), agora está dando certo,
e também estou conseguindo maximizar a tela (não totalmente no 43 X 80), obrigado Jose Quintas e Asimões.

Código: Selecionar todos

FUNCTION TESTEGET
    #include "inkey.ch"
    LOCAL codigo := 1, descricao := SPace(30), complemento := Space(30)
    LOCAL CST := 0, ncm := 0, cfop := 0, nome := Space(30)
    SAVE SCREEN
    ExpandirTela(43,80)
    @ 00,00 CLEAR TO 43,79
    @ 01,01 SAY "   Codigo:" GET codigo      pict "99999"
    @ 02,01 SAY "Descricao:" GET descricao   pict "@!"
    @ 03,01 SAY "    Compl:" GET complemento pict "@!"
    @ 04,01 SAY "      CST:" GET cst         pict "9999999999"
    @ 05,01 SAY "      NCM:" GET ncm         pict "99999999"
    @ 06,01 SAY "     CFOP:" GET cfop        pict "9999"
    @ 30,01 SAY "     Nome:" GET nome        pict "@!" 
    READ
    ExpandirTela(25,80)
    RESTORE SCREEN
    RETURN

STATIC FUNCTION ExpandirTela(linhas,colunas)
        Hb_gtReload( "WVG" )
  	SETMODE(linhas, colunas)
  	HB_GtInfo( HB_GTI_RESIZABLE, .F. )
  	screenWidth := HB_GTINFO( HB_GTI_DESKTOPWIDTH  )
  	screenHeight:= HB_GTINFO( HB_GTI_DESKTOPHEIGHT )
  	wvt_SetFont( "courier new"   , Round(( screenHeight / MaxRow() ),0)-4, Round(( screenWidth / MaxCol() ),0), 0 )
  	WVT_MAXIMIZE()
  	RETURN

HARBOUR 3.2.0(dev)

Mensagem por **asimoes** » 03 Mar 2018 12:19

Porter,

Acho que eu entendi o que você tá querendo fazer com a GTWVG, você quer o mesmo comportamento da GTWVT maximizando para área do desktop ? te informo que não funciona, você chega +- a isso com muito ajuste.

Outra coisa comenta essa linha:

HB_GtInfo( HB_GTI_RESIZABLE, .F. )

Se você não permitir o RESIZABLE não vai funcionar.

porter · Mensagem por **porter** » 03 Mar 2018 12:32

Acho que eu entendi o que você tá querendo fazer com a GTWVG, você quer o mesmo comportamento da GTWVT maximizando para área do desktop ? te informo que não funciona, você chega +- a isso com muito ajuste.

Exatamente isso, por enquanto com o GTWVG, o meu interesse seria inserir imagens, pelo que estive pesquisando,
com o GTWVT, isso não é possível.

Outra coisa comenta essa linha:

HB_GtInfo( HB_GTI_RESIZABLE, .F. )

Se você não permitir o RESIZABLE não vai funcionar.

Para que serve o RISIZABLE, comentei essa linha e não percebi mudanças.

Mensagem por **asimoes** » 03 Mar 2018 14:01

HB_GtInfo( HB_GTI_RESIZABLE, .F. ) é para não permitir que o usuário modifique o tamanho da janela pelas bordas, isso afeta o maximizar dependendo da posição onde vai ser chamado