Tipo de variável recebida por parametro

[rubens]

Bom dia...

Uma variável recebida por parametro qual a visibilidade/tipo dela? Local ?
Olha esse trecho:

Código: Selecionar todos

Function Main( cPath_Dbf, cEmpresa, cPath )
	Hb_Default( @cPath_dbf, '\DATASAC\' )
	Hb_Default( @cEmpresa, 'Backup' )	 
	Hb_Default( @cPath, 'D' )	 
        Teste()
	RETURN nil 

Function Teste()
    Alert( cPath_Dbf )
   Return nil

Dá erro de variável não encontrada... na linha do Alert( cPath_dbf ).
Daí para poder usar assim tenho que criar uma outra variável dentro do Main. Não posso mudar para Public ou Private uma variável que já existe.
vai virando uma lista de variáveis.
Alguma opção na compilação para que ao receber a variável ela fica visível para as subrotinas/funções?

Obrigado
Rubens

[Nascimento]

tente dessa forma:

Código: Selecionar todos

Function Main( )
 parameters cPath_Dbf, cEmpresa, cPath 
   Hb_Default( @cPath_dbf, '\DATASAC\' )
   Hb_Default( @cEmpresa, 'Backup' )    
   Hb_Default( @cPath, 'D' )    
        Teste()
   RETURN nil 

Function Teste()
    Alert( cPath_Dbf )
   Return nil

porque desta forma os parametros passam como variaveis privates entre os parenteses elas são locais

[alxsts]

Olá!

Uma variável recebida por parametro qual a visibilidade/tipo dela? Local ?

Sim, este é o comportamento padrão, exceto para arrays.

Código: Selecionar todos

Function Main()

local a := {1,2,3}
local b := 0

setmode(25,80)
cls

f1( a, b )

QOut( "a[1]", a[1], "b", b )

__wait()

return nil

function f1(x,y)

   x[1]++
   y++

return nil

Evite usar variáveis Private e Public. Dê preferência às variáveis dos tipos Local e Static. Se precisar usá-las para leitura em outras funções, passe-as como parâmetro. Neste caso, serão passadas por valor (by val).

Código: Selecionar todos

Function Main( cPath_Dbf, cEmpresa, cPath )

   Hb_Default( @cPath_dbf, '\DATASAC\' )
   Hb_Default( @cEmpresa, 'Backup' )  
   Hb_Default( @cPath, 'D' )  
   
   Teste( cPath_Dbf )   // passar parâmetro

 RETURN nil 

Function Teste( cPath_Dbf )  // recebe parâmetro por valor e cria variável LOCAL cPath_Dbf na função Teste()
   Alert( cPath_Dbf )
 Return nil

Se precisar atualizar as variáveis na função chamada, passe-as por referência (by ref), precedidas pelo carácter @, como mostrou o Nascimento.

O uso da sentença Parameters é obsoleto. Ao invés de

Código: Selecionar todos

	Function Main( )
	 parameters cPath_Dbf, cEmpresa, cPath   // --> Cria estas variáveis como PRIVATE

Use como você fez

Código: Selecionar todos

Function Main( cPath_Dbf, cEmpresa, cPath )