Exemplo simples de gtwvg

[JoséQuintas]

Pra quem se perdeu com os exemplos da gtwvg, aqui vai um exemplo simples.
Precisa só salvar um bmp na pasta com o nome policial.bmp.

Código: Selecionar todos

#include "wvtwin.ch"

PROCEDURE Main
   SetMode(25,80)
   CLS
   ToolBar()
   StatusBar()
   Button()
   Progressbar()
   Inkey(0)
   RETURN


STATIC FUNCTION Progressbar()
   LOCAL oProgressbar, nCont
   oProgressbar := wvtProgressbar():New( wvgSetAppWindow(), , 10, 10, 15, 60 )
   oProgressbar:Create()
   oProgressbar:Activate()
   FOR nCont = 1 TO 100
      oProgressBar:Display( nCont, 100 )
      Inkey(0.1)
   NEXT
   RETURN NIL

STATIC FUNCTION StatusBar()
   LOCAL oStatusBar, oPanel
   oStatusBar := wvgStatusBar():New( wvgSetAppWindow() ):Create( , , , , , .T. )
   oPanel := oStatusBar:GetItem(1)
   oPanel:Caption := "Test of status bar"
   RETURN NIL

STATIC FUNCTION Toolbar()
   LOCAL oToolbar, cDirIcon := "JPAICON\"
   oToolbar := WvgToolBar():New( wvgSetAppWindow(), , { 0, 0 }, { 0, 0 }, , .T. )
   oToolbar:style        := WVGTOOLBAR_STYLE_FLAT
   oToolbar:borderStyle  := WVGFRAME_RECT
   oToolbar:buttonWidth  := 32
   oToolbar:buttonHeight := 32
   oToolbar:imageWidth   := 32
   oToolbar:imageHeight  := 32
   oToolbar:showToolTips := .T.
   oToolbar:Create()
   oToolbar:addItem( "New"       , "policial.bmp" )
   oToolbar:AddItem( "Select"    , "policial.bmp" )
   oToolbar:AddItem()
   oToolbar:AddItem( "FontDlg"   , "policial.bmp" )
   oToolbar:AddItem( "Tools"     , "policial.bmp" )
   oToolbar:AddItem( "Index"     , "policial.bmp" )
   oToolbar:AddItem()
   oToolbar:AddItem( "Show"      , "policial.bmp" )
   oToolbar:AddItem( "Hide"      , "policial.bmp" )
   oToolbar:ButtonClick := { | oBtn | wapi_Messagebox( wapi_GetActiveWindow(), oBtn:Caption, "toolbar", MB_ICONASTERISK ) }
   RETURN NIL

STATIC FUNCTION Button()
   LOCAL oThisButton, nCont
   FOR nCont = 1 TO 10
      oThisButton := wvgPushButton():New()
      oThisButton:Caption := Ltrim( Str( nCont ) )
      oThisButton:PointerFocus := .F. 
      oThisButton:Create( , , { -18, -nCont * 5 }, { -2, -4 } )
      oThisButton:Activate := { | oBtn | wapi_MessageBox( wapi_GetActiveWindow(), oBtn:Caption, "button", MB_ICONASTERISK ) }
   NEXT
   RETURN NIL

arquivo hbp

Código: Selecionar todos

test.prg
errorsys.prg
gtwvg.hbc
-compr
-strip

[JoséQuintas]

a tela:

[JoséQuintas]

tem este outro exemplo, mas ainda não tentei simplificar.
Está misturado nos testes da gtwvg, o fonte faz parte do demowvg.
Como é a tal janela de diálogo, precisa de uma janela principal, que é a que está de fundo.

O problema é falta de exemplos simples e manuais.
Por exemplo: não existe fonte usando a tabcontrol, apesar de existir.
A wvg está preparada pra criar qualquer controle nela mesma, em fonte prg.
É por isso que eu acho a gtwvg a mais interessante das GUIs.
O chato é que criar controles não é pra nós pobres utilizadores de controles prontos.

[clodoaldomonteiro]

Quintas,

No arquivo .HBP cita o arquivo ErrorSys.PRG, que não existe no projeto.

[JoséQuintas]

pode usar a padrão mesmo, pro teste.