Necesito ayuda con el use de gtwvg

Adalberto · Mensagem por **Adalberto** » 02 Nov 2019 23:32

Buenas noches amigos del foro.

Estoy haciendo uso de:

aPaint:= {}
AAdd(aPaint, {NIL, {|| Wvt_DrawImage(00, 00, 24, 79, 'bFondo.jpg')}, NIL})   WvtSetPaint(aPaint)

Con este código obtengo un fondo de pantalla completo, necesito que ese fondo de pantalla permanezca 3 segundos y luego desaparezca y continuar 100% consola.

¿Como se hace para borrar ese fondo de pantalla?

Espero y agradezco la ayuda que me puedan brindar.

Muchas gracias!!!

Adalberto

Mensagem por **JoséQuintas** » 03 Nov 2019 00:04

Se esse fonte já resolve o que precisa, então basta limpar aPaint

Código: Selecionar todos

aPaint:= {}
AAdd(aPaint, {NIL, { || Wvt_DrawImage(00, 00, 24, 79, 'bFondo.jpg')}, NIL})   
WvtSetPaint( aPaint )

Inkey(3)
wvtSetPaint( {} )

Faça um teste também assim:

Código: Selecionar todos

Wvt_DrawImage(00, 00, 24, 79, 'bFondo.jpg')
Inkey(3)
CLS

Se for apresentação do aplicativo, talvez seja mais interessante manter em uma tela de login.

Adalberto · Mensagem por **Adalberto** » 03 Nov 2019 15:14

Buenas tardes Maestro JoséQuintas.

Muchas gracias por su ayuda.

Estoy leyendo un montón de Post y ayudas suyas, empecé ayer temprano, ya conseguí tener la imagen de presentación, y con su ayuda eliminar esa imagen, pero no tengo idea de como hacer un get/read para el loguin.

Mientras espero su colaboración seguiré leyendo los mensajes y estudiando sus fuentes.

Saludos desde la convulsionada Bolivia. (parece que mañana se desata el infierno en mi país, Dios nos ampare)

Adalberto.

Mensagem por **JoséQuintas** » 04 Nov 2019 00:58

Adalberto escreveu: pero no tengo idea de como hacer un get/read para el loguin.

É uma opção:

Código: Selecionar todos

aPaint:= {}
AAdd(aPaint, {NIL, { || Wvt_DrawImage(00, 00, 20, 79, 'bFondo.jpg')}, NIL})   
WvtSetPaint( aPaint )
@ 23, 30 SAY "user" GET cUser
@ 24, 30 SAY "Password" GET cPassword
READ
wvtSetPaint( {} )

Adalberto · Mensagem por **Adalberto** » 04 Nov 2019 14:51

Buenas tardes maestro JoséQuintas.

a su ejemplo le aumenté lo siguiente:

Código: Selecionar todos

aPaint:= {}
AAdd(aPaint, {NIL, { || Wvt_DrawImage(00, 00, 20, 79, 'bFondo.jpg')}, NIL})   
WvtSetPaint( aPaint )
//
cUser:= cPassWord:= SPACE(10)     // Sólo eso aumenté
//
@ 23, 30 SAY "user" GET cUser
@ 24, 30 SAY "Password" GET cPassword
READ
wvtSetPaint( {} )

Lamentablemente no corre, tal vez un Include, o algo así me falta.
Solo quiero poder hacer un GET/READ sobre la imagen.

Mil disculpas por las molestias, espero y agradezco su ayuda.

Adalberto

Mensagem por **JoséQuintas** » 04 Nov 2019 17:43

Adalberto escreveu:Solo quiero poder hacer un GET/READ sobre la imagen.

O texto cobre a imagem, ao mesmo tempo que se ficar repintando a imagem cobre o texto.
Terá que escolher entre um ou outro, ou parte da tela com texto e parte com imagem.

Código: Selecionar todos

Wvt_DrawImage(00, 00, MaxRow(), MaxCol(), 'bFondo.jpg')
cUser:= cPassWord:= SPACE(10)     // Sólo eso aumenté
@ 23, 30 SAY "user" GET cUser
@ 24, 30 SAY "Password" GET cPassword
READ

Nessa opção, a imagem é "temporariamente" desenhada, e o texto cobre a imagem.
Mas se minimizar, alterar tamanho da janela, ou qualquer outro movimento na janela, a imagem não vai ser repintada.
A melhor saída é dividir a tela em parte imagem, e parte texto.

Mensagem por **JoséQuintas** » 04 Nov 2019 17:47

Talvez uma janela wvgCrt() modal.
Desta forma vai ter uma janela sobre a imagem pra digitar usuário/senha.

Mensagem por **JoséQuintas** » 04 Nov 2019 18:11

Se não houvesse o problema de sumir imagem....

Imagem

Adalberto · Mensagem por **Adalberto** » 04 Nov 2019 19:47

Buenas noches Maestro JoséQuintas.

Consegui la funcion WvgCrt y lo implementé así:

Código: Selecionar todos

#INCLUDE "HBGTINFO.CH"
FUNCTION MAIN()
WvgCrt()
cUser:= SPACE(10)
cPassword:= SPACE(10)
@ 23, 30 SAY "user" 	GET cUser
@ 24, 30 SAY "Password" GET cPassword
READ
oCrt:destroy()
RETURN NIL
//
STATIC FUNCTION WvgCrt()
oCrt:= WvgCrt():Nuevo(,, {-1, -1}, {24,79},, .t.)
oCrt:lModal:= .T.
oCrt:Title:= 'EninSoft'
oCrt:icon:= 'Enin.Ico'
oCrt:create()
oCrt:ReSizable:= .T.
oCrt:Show()
CLS
RETURN NIL

No tuve éxito, al ejecutar me dice que la variable lModal no existe, da error en oCrt:Title y en oCrt:Icon; seguiré buscando, leyendo y probando todo lo que encuentre, pero también estaré esperando vuestra ayuda.

Muchas gracias Maestro.

Adalberto

Mensagem por **JoséQuintas** » 04 Nov 2019 20:35

Código: Selecionar todos

STATIC FUNCTION WvgCrt()

Criou uma função com o nome da função da GTWVG???? assim não funciona.

Código: Selecionar todos

oCrt:= WvgCrt():Nuevo(,, {-1, -1}, {24,79},, .t.)

Não existe Nuevo(), só existe New()

Código: Selecionar todos

FUNCTION MAIN()

   CLS
   Wvt_DrawImage(00, 00, MaxRow(), MaxCol(), 'lucy.jpg' )
   Login()
   ? "ok"
   Inkey(0)

   RETURN NIL

STATIC FUNCTION Login()

   LOCAL cUser:= Space(10), cPassword:= Space(10), GetList := {}, oCrt

   oCrt:= WvgCrt():New(,, { 10, 30 }, { 4, 20 },, .t. )
   oCrt:lModal:= .T.
   oCrt:Title:= 'Login'
   oCrt:icon:= 'Enin.Ico'
   oCrt:ReSizable:= .F.
   oCrt:create()
   SetColor( "W/B*,N/W,,,W/B*" )
   CLS
   @ 2, 2 SAY "user"    GET cUser
   @ 3, 2 SAY "Password" GET cPassword
   READ
   oCrt:Destroy()

   RETURN NIL

Mensagem por **JoséQuintas** » 04 Nov 2019 20:45

Ou assim, usando WITH OBJECT

Código: Selecionar todos

FUNCTION MAIN()

   CLS
   Wvt_DrawImage(00, 00, MaxRow(), MaxCol(), 'lucy.jpg' )
   Login()
   ? "ok"
   Inkey(0)

   RETURN NIL

STATIC FUNCTION Login()

   LOCAL cUser:= Space(10), cPassword:= Space(10), GetList := {}, oCrt

   WITH OBJECT oCrt := WvgCrt():New(,, { 17, 30 }, { 4, 20 },, .t. )
      :lModal    := .T.
      :Title     := 'Login'
      :icon      := 'icojpa.Ico'
      :ReSizable := .F.
      :Create()
   ENDWITH

   SetColor( "W/B*,N/W,,,W/B*" )
   CLS
   @ 2, 2 SAY "user"    GET cUser
   @ 3, 2 SAY "Password" GET cPassword
   READ
   oCrt:Destroy()

   RETURN NIL

Mensagem por **JoséQuintas** » 04 Nov 2019 21:04

Completo.
Reduzi a imagem 16 vezes, no teste era 1.20MB, 7216 X 5412

test.zip: (1.03 MiB) Baixado 304 vezes

Mensagem por **asimoes** » 05 Nov 2019 08:29

Quintas qual é o nome da moça? não quero saber do código, kkk

Adalberto · Mensagem por **Adalberto** » 05 Nov 2019 14:42

) Aseimoes, buenas tardes, la chica se llama Lucy.

Maestro JoséQuintas, buenas tardes.

Ahora sí funcionó muy bien, le agradezco muchisimo, ahora me pondré a buscar y estudiar como poner mensajes en modo gráfico; MsgInfo(), MsgYesNo()

Gracias nuevamente, Dios lo bendiga.

Adalberto

Mensagem por **JoséQuintas** » 05 Nov 2019 17:10

Não gosto delas, mas uso...

Código: Selecionar todos

FUNCTION MsgYesNo( cText )

   LOCAL lValue

   lValue := wapi_MessageBox( wvgSetAppWindow():hWnd, cText, "Confirmação", WIN_MB_YESNO + WIN_MB_ICONQUESTION 

   RETURN lValue

FUNCTION MsgExclamation( cText )

   wapi_MessageBox( wvgSetAppWindow():hWnd, cText, "Atenção", WIN_MB_ICONASTERISK )

   RETURN NIL

FUNCTION MsgWarning( cText )

   wapi_MessageBox( wvgSetAppWindow():hWnd, cText, "Atenção", WIN_MB_ICONEXCLAMATION )

   RETURN NIL

FUNCTION MsgStop( cText )

   wapi_MessageBox( wvgSetAppWindow():hWnd, cText, "Atenção", WIN_MB_ICONHAND )

   RETURN NIL