Colocando .BMP no Browse em HWGUI

[Fernando queiroz]

Depois de muito tentar até que consegui colocar .BMP em um BROWSE

no começo da rotina colocar

Código: Selecionar todos

Local bCol1 := {|o,h,x1,y1,x2,y2|
	Local oBmp
	hwg_Fillrect( h, x1, y1, x2, y2, oBrowse3:brush:handle )
	   oBmp := IF(oBrowse3:aArray[oBrowse3:nCurrent,7] =  '1', HBitmap():AddResource( "goodmark" ), HBitmap():Addresource( "badmark" ) )
	   hwg_Drawbitmap( h, oBmp:handle,, x1+20, y1+4, oBmp:nWidth, oBmp:nHeight )
	RETURN Nil
 }

depois no browse montar da seguinte forma

Código: Selecionar todos

		@ 5,357 BROWSE oBrowse3 ARRAY SIZE 1000, 237 ;
			STYLE WS_TABSTOP      
	
		oBrowse3:oStyleHead := HStyle():New( { 0xffffff, 0xbbbbbb }, 1,, 0.4, 16759929 )
		oBrowse3:oFont := HFont():Add( '',0,-15,700,,,)
		oBrowse3:aArray := {}

		oBrowse3:AddColumn( HColumn():New( "",,"C",6,0,,,0, ) )
		oBrowse3:AddColumn( HColumn():New( "RECIBO",hwg_ColumnArBlock(),"N",12,0,.F.,1,2,,,,,,))
		oBrowse3:AddColumn( HColumn():New( "ID",hwg_ColumnArBlock(),"N",12,0,.F.,1,2,,,,,,))
		oBrowse3:AddColumn( HColumn():New( "CLIENTE/FORNECEDOR/VENDEDOR",hwg_ColumnArBlock(),"C",50,0,.F.,,, ) )
		oBrowse3:AddColumn( HColumn():New( "TOTAL",hwg_ColumnArBlock(),'N',16, 2 ,.F.,2,2,'@E 99,999,999,999.99',,,,,,,,,))
		oBrowse3:AddColumn( HColumn():New( "HISTORICO",hwg_ColumnArBlock(),"C",80,0,.F.,,, ) )

		oBrowse3:aColumns[1]:setPaintCB( PAINT_LINE_ALL, bCol1 )

e na carga do BROWSE por ARRAY montar assim, neste caso estou usando o MARIADB

Código: Selecionar todos

	cQuery1:="SELECT  "
	cQuery1+="movcaixa.TIPMOV, "
	cQuery1+="movcaixa.MOVCAIXA_Id, "
	cQuery1+="movcaixa.CLIFOR, "
	cQuery1+="movcaixa.NRAZ_SOC, "
	cQuery1+="movcaixa.VALOR, "
	cQuery1+="movcaixa.HISTOR "
	cQuery1+="FROM movcaixa "
	cQuery1+="WHERE movcaixa.DATMOV = '" + Hb_DTOC(dDATCAI, "YYYY-MM-DD") + "' AND movcaixa.TURCAI = '" + STRZERO(nTURCAI,1,0) + "'"
	oQuery3:= oServer:Execute(cQuery1)

	DO WHILE ! oQuery3:Eof()
		aAdd( aResult3,{"",;
						oQuery3:Fields( "MOVCAIXA_Id" ):Value,;
						oQuery3:Fields( "CLIFOR" ):Value,;
						oQuery3:Fields( "NRAZ_SOC" ):Value,;
						oQuery3:Fields( "VALOR" ):Value,;
						oQuery3:Fields( "HISTOR" ):Value,;
						oQuery3:Fields( "TIPMOV" ):Value} )

		oQuery3:MoveNext()
	ENDDO

	oBrowse3:aArray := aResult3

[JoséQuintas]

Demorei um pouquinho pra entender, mas entendi.

Nesse caso é criado um codeblock, que recebe coordenadas da linha do browse, e faz o desenho.
esta função repete o codeblock pra cada linha do browse, selecionando a imagem conforme foi definido no bcol1.

Código: Selecionar todos

oBrowse3:aColumns[1]:setPaintCB( PAINT_LINE_ALL, bCol1 )

E é sério, esquema parecido ao da GTWVG.
É interessante.
Acredito que tenha outra forma, pra quando as imagens não seguem um padrão único.

[Itamar M. Lins Jr.]

Uso, a mais de 6 anos...
Depois posto a tela, estou no linux.

Código: Selecionar todos

   obitAzul     := hbitmap():AddResource( 'BolaAzul' )
   obitVermelho := hbitmap():AddResource( 'BolaVermelha' )
   obitBranco   := hbitmap():AddResource( 'BolaBranca' )
   obitAmarelo  := hbitmap():AddResource( 'BolaAmarela' )
   obitVerde    := hbitmap():AddResource( 'BolaVerde' ) 
   obitPreto    := hbitmap():AddResource( 'BolaPreta' )
   obitCinza    := hbitmap():AddResource( 'BolaCinza' )
   oUnlock      := hbitmap():AddResource( 'Unlock' )

     Add columnEx {||" "} to oBrw ;
      Header ' ' Type 'C' Length 2 Picture ' ' ;
      Justify Line DT_RIGHT  Justify Head DT_CENTER

   oBrw:aColumns[2]:aBitmaps := ;
        { { {|| SinalPreto() }, oBitPreto }, { {|| SinalAmarelo() }, oBitAmarelo }, { {|| SinalVermelho() }, oBitVermelho },{ {|| SinalAzul() }, oBitAzul }, { {|| SinalVerde() }, oBitVerde } }

//Criar suas funções da forma que deseja
Static Function SinalVermelho
Local lRet := .f.
if eq->quantidade < 0
        lRet := .t.
endif
return lRet

Fica umas bolinhas coloridas.
Fiz, assim da época que trabalhei na ToTvs...Gostei do browse deles e fiz parecido.

Saudações,
Itamar M. Lins Jr.

[Fernando queiroz]

Dei uma modificada criando um ARRAY para guardar os .BMP e vou pegando de acordo com o tipo

Código: Selecionar todos

	, aBitmaps:={HBitmap():AddResource( "goodmark" ), HBitmap():Addresource( "badmark" ), HBitmap():Addresource( "PEOPLEBMP" ), HBitmap():Addresource( "Remove" )};


Local bCol1 := {|o,h,x1,y1,x2,y2|
	Local oBmp, nBitmaps:=val(oBrowse3:aArray[oBrowse3:nCurrent,7])
		hwg_Fillrect( h, x1, y1, x2, y2, oBrowse3:brush:handle )
	   	oBmp := aBitmaps[nBitmaps] 
	   	hwg_Drawbitmap( h, oBmp:handle,, x1+20, y1+4, oBmp:nWidth, oBmp:nHeight )
	RETURN Nil
 }

ficou bem interressante

[Itamar M. Lins Jr.]

Ola!
Gostei, tá pegando esses bitmaps onde ?

Saudações,
Itamar M. Lins Jr.

[Fernando queiroz]

Ola!
Gostei, tá pegando esses bitmaps onde ?

Saudações,
Itamar M. Lins Jr.

Se você quiser posso te mandar

Disponha
FERNANDO QUEIROZ

[alxsts]

Olá!

Muito bom! Parabéns!

Dúvidas:
1 - é possível colocar o bitmap em qualquer coluna? Ou apenas na primeira?
2 - é possível colocar bitmaps em várias colunas, na mesma linha?

Em algum lugar, vi que, na HwGUI, estas possibilidades existem apenas no componente Grid. Gostaria de confirmar.

[Itamar M. Lins Jr.]

Ola!
Qualquer coluna, e varias colunas. Então 1)sim, 2)sim.

Isso é antigo na Hwgui. Tem exemplo no tutor.
E é no browse que eu uso, nunca usei grid.

Saudações,
Itamar M. Lins Jr.

[asimoes]

Meu exemplo usando jpg, png ou bmp

[Fernando queiroz]

DEI uma melhorada no codeblock dos icones

Código: Selecionar todos

	, aBitmaps:={HBitmap():AddResource( "goodmark" ), HBitmap():Addresource( "badmark" ), HBitmap():Addresource( "PEOPLEBMP" ), HBitmap():Addresource( "Remove" )};


LOCAL bCol1 := {|oBmp, h,x1,y1,x2,y2| oBmp:=aBitmaps[val(oBrowse3:aArray[oBrowse3:nCurrent,7])], ;
                                   hwg_Fillrect( h, x1, y1, x2, y2, oBrowse3:brush:handle ), ;
	                               hwg_Drawbitmap( h, oBmp:handle,, x1+20, y1+4, oBmp:nWidth, oBmp:nHeight ) }