Abrir Cupom Fiscal - dúvidas *** RESOLVIDO ***

Aqui você poderá oferecer suas Contribuições, Dicas e Tutoriais (Texto ou Vídeo) que sejam de interesse de todos.

Moderador: Moderadores

Responder
Avatar do usuário
software_facil
Usuário Nível 3
Usuário Nível 3
Mensagens: 211
Registrado em: 23 Fev 2005 12:19
Localização: Curitiba/PR
Contato:
Contato software_facil

Abrir Cupom Fiscal - dúvidas *** RESOLVIDO ***

Mensagem por software_facil »

Bom dia,

Implementei os comandos para a ECF MP 25 FI da Bematech, porém, quando fecho o cupom (impressão), e logo em seguida quero abrir outro, não sai impresso os dados de abertura de cupom, mas o mesmo é aberto, visto as mensagens de erro que retornam, onde posso estar falhando ?

Abraços

Marcelo Neves
Editado pela última vez por software_facil em 06 Abr 2009 21:06, em um total de 1 vez.
messenger : software_facil@hotmail.com
Voltar ao topo
Avatar do usuário
alaminojunior
Colaborador
Colaborador
Mensagens: 1717
Registrado em: 16 Dez 2005 21:26
Localização: Ubatuba - SP

Re: Abrir Cupom Fiscal - dúvidas

Mensagem por alaminojunior »

quando fecho o cupom (impressão), e logo em seguida quero abrir outro, não sai impresso os dados de abertura de cupom, mas o mesmo é aberto
visto as mensagens de erro que retornam
Precisa ter certeza se ele realmente foi fechado. Pode ser que ele não tenha completado o fechamento.
Enfim, precisaria de mais detalhes, como o meio de comunicação utilizado e analisar também os retornos do ECF. Vai ver, alguma função retornou algum erro, e você está tentando seguir em frente, sem antes tratar.
Compilador xHarbour 1.2.3 + Embarcadero C++ 7.30
MySQL c/ SQLRDD
HwGui + GTWVG
Voltar ao topo
Avatar do usuário
software_facil
Usuário Nível 3
Usuário Nível 3
Mensagens: 211
Registrado em: 23 Fev 2005 12:19
Localização: Curitiba/PR
Contato:
Contato software_facil

Re: Abrir Cupom Fiscal - dúvidas

Mensagem por software_facil »

Utilizo esse código, que era usado para MP-20, para manipular a MP-25, e talvez por isso esteja dando o problema apresentado acima :

Código: Selecionar todos

*******************************************************************
function ifcomunicar(ifbuffer_a_ser_enviado,iftam_a_ser_ret)
*******************************************************************
* Funcao de coneccao direta com impressora fiscal Bematech MP20
*

   if iftam_a_ser_ret=NIL
      iftam_a_ser_ret=0
   EndIF

   ifspool := xxspool
   ifporta := fopen(ifspool, 2)

   if ferror () != 0
      Winquest('ATEN€AO;Problemas de Comunica‡„o com a ECF;Tecle ENTER')
      fClose(ifPorta)
      *Inkey(5)
      Return '999999999'
   endif

   iftamanho_de_retorno := 0

   fwrite(ifporta, @ifbuffer_a_ser_enviado, len(ifbuffer_a_ser_enviado))
   iffinal=Space(0)
   ifretorno_impressora=Space(1)
   For ifcontador=1 to 3
       fread(ifporta,@ifretorno_impressora,1)
       if ifcontador=1
	  if StrZero(Asc(ifretorno_impressora),3,0) # '006'
	     Winquest('ATEN€AO;A impressora ECF n„o est  respondendo;Ela pode estar Desligada;ou;O Arquivo MP20DRV.EXE n„o foi carregado;Se ap¢s essas duas verifica‡”es;o problema persistir, entre;em contato com o Suporte T‚cnico;Tecle ENTER')
	     fClose(ifPorta)
	     *Inkey(1)
	     Return '999999999'
	  EndIF
       EndIF
       iffinal=iffinal+StrZero(Asc(ifretorno_impressora),3,0)
   next ifcontador

   For ifcontador=1 to iftam_a_ser_ret
       fread(ifporta,@ifretorno_impressora,1)
       iffinal=iffinal+ifretorno_impressora
   next ifcontador

   fClose(ifPorta)

return iffinal

******************************************************************************
function if_Status()
*********
* Verifica o Status atual da impressora
*

   ifRetorno=ifcomunicar(__IniProt+ '19' +__FimProt)

Return ifRetorno

******************************************************************************
function if_abr_cupom()
*********
* Abre Cupom Fiscal
*
*Pre-Requisitos
*
*O Ultimo Cupom Fiscal devera estar fechado
*Nao podera ter ocorrido uma reducao Z no dia
*

   ifRetorno=ifcomunicar(__IniProt+ '00' +__FimProt)

Return ifRetorno

******************************************************************************
function if_v_it_gen(ifcodigo,ifdescricao,ifaliquota,ifquantidade,ifint_fra,ifvalor,ifdesconto,ifperc_valor)
*********
* Efetua a Venda de um item generico
*
* ifcodigo=C(13)                   -Codigo do Produto
* ifdescricao=C(29)                -Descricao do Produto
* ifaliquota=C(2)                  -Aliquota do Produto (T01, T02, ...)
* ifquantidade=N(4,0) ou N(8,3)    -Qtd de Produtos
* ifint_fra=C(1)                   -Qtd de Produtos Com Casas Decimais ou nao
* ifvalor=N(9,2)                   -Valor Unitario do Produto
* ifdesconto=N(5,2) ou N(9,2)      -Desconto do produto
* ifperc_valor=C(1)                -Desconto em Porcentagem ou Valor
*
*Pre-requisitos
*
*O Cupom fiscal devera estar aberto
*A Aliquota solicitada deve estar programada na impressora

   Do case
      case Len(ifcodigo)>13
	   Return '999999999'
      case len(ifdescricao)#29
	   return '999999999'
      case len(ifaliquota)#2
	   return '999999999'
      case !(ifint_fra$'FI')
	   return '999999999'
      case ifquantidade<=0
	   return '999999999'
      case ifvalor<=0
	   return '999999999'
      case ifdesconto<0
	   return '999999999'
      case !(ifperc_valor$'%$')
	   return '999999999'
   EndCase

   ifcodigo=ifcodigo+Repl('0',13-Len(ifcodigo))
   ifcodigo=StrTran(ifcodigo,' ','0')

   if ifint_fra='I'
      ifquantidade=StrTran(StrTran(StrTran(StrZero(ifquantidade,4,0),'.',''),',','') ,' ','')
     Else
      ifquantidade=StrTran(StrTran(StrTran(StrZero(ifquantidade,8,3),'.',''),',','') ,' ','')
   EndIF

   ifvalor=StrTran(StrTran(StrTran(StrZero(ifvalor,9,2),'.',''),',','') ,' ','')

   if ifperc_valor='%'
      ifdesconto=StrTran(StrTran(StrTran(StrZero(ifdesconto,5,2),'.',''),',','') ,' ','')
     Else
      ifdesconto=StrTran(StrTran(StrTran(StrZero(ifdesconto,9,2),'.',''),',','') ,' ','')
   EndIF

   ifRetorno=ifcomunicar(__IniProt+'09|'+ifcodigo+'|'+ifdescricao+'|'+ifaliquota+'|'+ifquantidade+'|'+ifvalor+'|'+ifdesconto+__FimProt)

Return ifRetorno

******************************************************************************
function if_v_it_comb(ifcodigo,ifdescricao,ifaliquota,ifquantidade,ifvalor,ifdesconto,ifperc_valor)
*********
* Efetua a Venda de um item tipo combustivel
*
* ifcodigo=C(13)                   -Codigo do Produto
* ifdescricao=C(29)                -Descricao do Produto
* ifaliquota=C(2)                  -Aliquota do Produto (T01, T02, ...)
* ifquantidade=N(4,0) ou N(8,3)    -Qtd de Produtos
* ifvalor=N(9,3)                   -Valor Unitario do Produto
* ifdesconto=N(5,2) ou N(9,2)      -Desconto do produto
* ifperc_valor=C(1)                -Desconto em Porcentagem ou Valor
*
*Pre-requisitos
*
*O Cupom fiscal devera estar aberto
*A Aliquota solicitada deve estar programada na impressora

   Do case
      case Len(ifcodigo)>13
	   Return '999999999'
      case len(ifdescricao)#29
	   return '999999999'
      case len(ifaliquota)#2
	   return '999999999'
      case ifquantidade<=0
	   return '999999999'
      case ifvalor<=0
	   return '999999999'
      case ifdesconto<0
	   return '999999999'
      case !(ifperc_valor$'%$')
	   return '999999999'
   EndCase

   ifcodigo=ifcodigo+Repl('0',13-Len(ifcodigo))
   ifcodigo=StrTran(ifcodigo,' ','0')

   ifquantidade=StrTran(StrTran(StrTran(StrZero(ifquantidade,8,3),'.',''),',','') ,' ','')

   ifvalor=StrTran(StrTran(StrTran(StrZero(ifvalor,9,3),'.',''),',','') ,' ','')

   if ifperc_valor='%'
      ifdesconto=StrTran(StrTran(StrTran(StrZero(ifdesconto,5,2),'.',''),',','') ,' ','')
     Else
      ifdesconto=StrTran(StrTran(StrTran(StrZero(ifdesconto,9,2),'.',''),',','') ,' ','')
   EndIF

   ifRetorno=ifcomunicar(__IniProt+'56|'+ifcodigo+'|'+ifdescricao+'|'+ifaliquota+'|'+ifquantidade+'|'+ifvalor+'|'+ifdesconto+__FimProt)

Return ifRetorno

******************************************************************************
function if_fecs_cupom(ifDA,ifPV,ifdesconto,ifvalor,ifmensagem)
*********
* Efetua o Fechamento de um cupom fiscal sem formas de pagamento
*
* ifDA=C(1)                          -Desconto ou Acrescimo
* ifPV=C(1)                          -Desconto ou Acrescimo em Vlr ou Porcentagem
* ifDesconto=N(5,2) ou N(15,2)       -Valor do Acrescimo ou Desconto
* ifValor=N(15,2)                    -Valor pago
* ifMensagem=C(495 no maximo)        -Mensagem promocional
*
*Pre-Requisitos
*
*O Cupom Fiscal devera estar Aberto
*Caso nao tenha itens vendidos, o cupom sera automaticamente cancelado
*

   Do Case
      Case !(ifDA$'DA')
	   Return '999999999'
      Case !(ifPV$'%$')
	   Return '999999999'
      //Case ifdesconto<0
      //	   Return '999999999'
      //Case ifValor<0
      //	   Return '999999999'
   EndCase

   if ifPV='%'
      ifdesconto=StrTran(StrTran(StrTran(StrZero(ifdesconto,5,2),'.',''),',','') ,' ','')
     Else
      ifdesconto=StrTran(StrTran(StrTran(StrZero(ifdesconto,15,2),'.',''),',','') ,' ','')
   EndIF
   ifvalor=StrTran(StrTran(StrTran(StrZero(ifvalor,15,2),'.',''),',','') ,' ','')
   ifmensagem=AllTrim(ifmensagem)

  if ifPV='%'
   ifRetorno=ifcomunicar(__IniProt+ '10|'+ifdesconto+'|'+ifvalor+'|'+ifDA+'|'+ifmensagem+Chr(10)+__FimProt)
  Else
   ifRetorno=ifcomunicar(__IniProt+ '10|0000|'+ifvalor+'|'+ifDA+'|'+ifdesconto+'|'+ifmensagem+Chr(10)+__FimProt)
  EndIF

Return ifRetorno

******************************************************************************
function if_fecc_icupom(ifDA,ifPV,ifdesconto)
*********
* Efetua o INICIO do fechamento de um cupom fiscal com formas de pagamento
*
* ifDA=C(1)                          -Desconto ou Acrescimo
* ifPV=C(1)                          -Desconto ou Acrescimo em Vlr ou Porcentagem
* ifDesconto=N(5,2) ou N(15,2)       -Valor do Acrescimo ou Desconto
*
*Pre-Requisitos
*
*O Cupom Fiscal devera estar Aberto
*Caso nao tenha itens vendidos, o cupom sera automaticamente cancelado
*

*   Do Case
*      Case !(ifDA$'DA')
*	   Return '999999999'
*      Case !(ifPV$'%$')
*	   Return '999999999'
*      Case ifdesconto<0
*	   Return '999999999'
*   EndCase
*
*   if ifPV='%'
*      ifdesconto=StrTran(StrTran(StrTran(StrZero(ifdesconto,5,2),'.',''),',','') ,' ','')
*     Else
*      ifdesconto=StrTran(StrTran(StrTran(StrZero(ifdesconto,15,2),'.',''),',','') ,' ','')
*   EndIF

   ifRetorno=ifcomunicar(__IniProt+ '32|'+ifDA+'|'+ifdesconto+__FimProt)

Return ifRetorno

******************************************************************************
function if_fecc_pcupom(ifPgto,ifValor)
*********
* Efetua o FORMAS DE PAGAMENTO do fechamento de um cupom fiscal com formas de pagamento
*
* ifPgto=C(2)                       -Descricao da forma de pagamento
* ifValor=N(15,2)                   -Valor do Pgto
*
*Pre-Requisitos
*
*O Cupom Fiscal devera estar Aberto
*Caso nao tenha itens vendidos, o cupom sera automaticamente cancelado
*

   Do Case
      Case Empt(ifPgto)
	   Return '999999999'
      Case ifValor<=0
	   Return '999999999'
   EndCase

   ifValor=StrTran(StrTran(StrTran(StrZero(ifValor,15,2),'.',''),',','') ,' ','')

   ifRetorno=ifcomunicar(__IniProt+ '72|'+ifPgto+'|'+ifValor+__FimProt)

Return ifRetorno

******************************************************************************
function if_fecc_tcupom(ifMensagem)
*********
* Efetua o TERMINO do fechamento de um cupom fiscal com formas de pagamento
*
* ifMensagem=C(492)                  -Mensagem Promocional
*
*Pre-Requisitos
*
*O Cupom Fiscal devera estar Aberto
*Caso nao tenha itens vendidos, o cupom sera automaticamente cancelado
*

   Do Case
      Case Empt(ifMensagem)
	   Return '999999999'
   EndCase

   ifMensagem=AllTrim(ifMensagem)

   ifRetorno=ifcomunicar(__IniProt+ '34|'+ifMensagem+Chr(10)+Chr(13)+__FimProt)

Return ifRetorno

******************************************************************************
function if_Esc_ItAnt()
*********
* Efetua o cancelamento de um item anterior
*
*Pre-Requisitos
*
*O Cupom Fiscal devera estar Aberto
*Ao menos 01 (um) item devera ter sido vendido
*Nao devera ter ocorrido cancelamento de item imediatamente anterior
*

   ifRetorno=ifcomunicar(__IniProt+ '13' +__FimProt)

Return ifRetorno

******************************************************************************
function if_Esc_ItGen( pNumItem )
*********
* Efetua o cancelamento de um item gen‚rico
*
* pNumItem = 4 Bytes (nø do ¡tem a ser cancelado)
*
* Pre-Requisitos
*
* O Cupom Fiscal devera estar Aberto
* Ao menos 02 (dois) itens deverÆo ter sido vendidos
* Nao devera ter ocorrido cancelamento de item imediatamente anterior
*

   ifRetorno=ifcomunicar(__IniProt+ '31|'+pNumItem +__FimProt)

Return ifRetorno

******************************************************************************
function if_Esc_Cupom()
*********
* Efetua o cancelamento do ultimo Cupom fiscal
*
*Pre-Requisitos
*
*O ultimo Cupom Fiscal devera estar fechado
*Ao menos 01 (um) item devera ter sido vendido
*Nao devera ter ocorrido Reducao Z, nem leitura X, apos a emissao do cupom fiscal
*

   ifRetorno=ifcomunicar(__IniProt+ '14' +__FimProt)

Return ifRetorno

******************************************************************************
function if_LEX()
*********
* Efetua a Leitura X
*
*Pre-Requisitos
*
*O ultimo Cupom Fiscal devera estar Fechado
*

   ifRetorno=ifcomunicar(__IniProt+ '06' +__FimProt)

Return ifRetorno

******************************************************************************
function if_RedZ()
*********
* Efetua a Reducao Z
*
*Pre-Requisitos
*
*O ultimo Cupom Fiscal devera estar Fechado
*APOS A EMISSAO DA REDUCAO Z, NAO E' MAIS ACEITO EFETUAR VENDAS, POR ISTO
*TOME MUITO CUIDADO, PARA NAO EMITI-LA NO MEIO DO DIA, FICANDO O RESTO DO DIA
*COM A IMPRESSORA TRAVADA, A REDUCAO Z SO PODERA SER FEITA NO FIM DO DIA
*

   ifRetorno=ifcomunicar(__IniProt+ '05' +__FimProt)

Return ifRetorno

******************************************************************************
function if_Moeda(ifop)
*********
* Efetua a Troca da Moeda Atual
*
* ifop=C(2)           -Simbolo da Moeda
*
*Pre-Requisitos
*
*Nao podera ter cupom fiscal aberto
*

   ifRetorno=ifcomunicar(__IniProt+'01'+ifop+__FimProt)

Return ifRetorno

******************************************************************************
function if_ArTr(ifop)
*********
* Altera a Opcao de (A)rredondamento ou (T)runcamento
*
* ifop=C(1)            -(A)rredondamento ou (T)runcamento
*
*Pre-Requisitos
*
*Este comando so pode ser executado caso nao tenha havido movimento no dia,
*ou seja, apos uma reducao Z
*
*
* EXEMPLO:           QTD..: Kg 1,249
*                    VLR..: R$ 2,00
*                    Total: R$ 2,498
* C/Arredondamento   Total: R$ 2,50
* C/Truncamento      Total: R$ 2,49
*
*

   if ifop='A'
      ifRetorno=ifcomunicar(__IniProt+ '39|1' +__FimProt,14)
     Else
      ifRetorno=ifcomunicar(__IniProt+ '39|0' +__FimProt,14)
   EndIF

Return ifRetorno

******************************************************************************
function if_le_serie()
*********
* Retorna o Nr de Serie da Impressora
*
*Retorno: Posicao(10) com (14)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|00' +__FimProt,14)

Return ifRetorno

******************************************************************************
function if_le_CgcIe()
*********
* Retorna o Nr do CGC e Inscricao Estadual
*
*Retorno: Posicao(10) com (33)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|02' +__FimProt,33)

Return ifRetorno

******************************************************************************
function if_le_GT()
*********
* Retorna o Grande Total
*
*Retorno: Posicao(10) com (18)Espacos (Sendo os dois ultimos, correspondentes
*                                      as casas decimais)
*

   ifRetorno=ifcomunicar(__IniProt+ '35|03' +__FimProt,18)

Return ifRetorno

******************************************************************************
function if_le_VCanc()
*********
* Retorna o Valor de Cancelamentos
*
*Retorno: Posicao(10) com (14)Espacos (Sendo os dois ultimos, correspondentes
*                                      as casas decimais)
*

   ifRetorno=ifcomunicar(__IniProt+ '35|04' +__FimProt,14)

Return ifRetorno

******************************************************************************
function if_le_VDesc()
*********
* Retorna o Valor de Descontos
*
*Retorno: Posicao(10) com (14)Espacos (Sendo os dois ultimos, correspondentes
*                                      as casas decimais)
*

   ifRetorno=ifcomunicar(__IniProt+ '35|05' +__FimProt,14)

Return ifRetorno

******************************************************************************
function if_le_Seq()
*********
* Retorna o Numero do Ultimo Cupom Fiscal impresso
*
*Retorno: Posicao(10) com (6)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|06' +__FimProt,6)

Return ifRetorno

******************************************************************************
function if_le_CCanc()
*********
* Retorna o Numero de Cupons Cancelados
*
*Retorno: Posicao(10) com (4)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|08' +__FimProt,4)

Return ifRetorno

******************************************************************************
function if_le_RedZ()
*********
* Retorna o Numero de Reducoes Z efetuadas
*
*Retorno: Posicao(10) com (4)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|09' +__FimProt,4)

Return ifRetorno

******************************************************************************
function if_le_IntTec()
*********
* Retorna o Numero de Intervencoes Tecnicas
*
*Retorno: Posicao(10) com (4)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|10' +__FimProt,4)

Return ifRetorno

******************************************************************************
function if_le_UltITV()
*********
* Retorna o Numero do Ultimo Item Vendido
*
*Retorno: Posicao(10) com (4)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|12' +__FimProt,4)

Return ifRetorno

******************************************************************************
function if_le_Moeda()
*********
* Retorna a Moeda Atual
*
*Retorno: Posicao(10) com (2)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|16' +__FimProt,2)

Return ifRetorno

******************************************************************************
function if_le_MinL()
*********
* Retorna o Numero de Minutos que a impressora esta ligada
*
*Retorno: Posicao(10) com (4)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|18' +__FimProt,4)

Return ifRetorno

******************************************************************************
function if_le_MinI()
*********
* Retorna o Numero de Minutos que a impressora esta Imprimindo
*
*Retorno: Posicao(10) com (4)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|19' +__FimProt,4)

Return ifRetorno

******************************************************************************
function if_le_DtHr()
*********
* Retorna a Data e a Hora Atual
*
*Retorno: Posicao(10) com (12)Espacos  sendo (DDMMAAHHMMSS)
*

   ifRetorno=ifcomunicar(__IniProt+ '35|23' +__FimProt,12)

Return ifRetorno

******************************************************************************
function if_le_NCaixa()
*********
* Retorna o N£mero do Caixa (ECF)
*
*Retorno: Posicao(10) com (04)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|14' +__FimProt,4)

Return ifRetorno

******************************************************************************
function if_le_NLoja()
*********
* Retorna o N£mero da Loja (ECF)
*
*Retorno: Posicao(10) com (04)Espacos
*

   ifRetorno=ifcomunicar(__IniProt+ '35|15' +__FimProt,4)

Return ifRetorno

******************************************************************************
function if_le_UltZ()
*********
* Retorna a Data e a Hora da Ultima Reducao Z
*
*Retorno: Posicao(10) com (12)Espacos  sendo (DDMMAAHHMMSS)
*

   ifRetorno=ifcomunicar(__IniProt+ '35|26' +__FimProt,12)

Return ifRetorno

******************************************************************************
function if_Supr(ifVlr)
*********
* Efetua um Suprimento de Dinheiro no Caixa
*
* ifVlr=V(15,2)           -Valor do Suprimento
*
*Pre-Requisitos
*
*Nao podera ter cupom fiscal aberto
*

   if ifVlr<=0
      Return '999999999'
   EndIF

   ifvlr=StrTran(StrTran(StrTran(StrZero(ifvlr,15,2),'.',''),',','') ,' ','')

   ifRetorno=ifcomunicar(__IniProt + "25|SU|"+ifvlr + __FimProt)


Return ifRetorno

******************************************************************************
function if_FormaPag(pParametro)
*********
* Carrega as Formas de Pagamento na Impressora
*

   ifRetorno=ifcomunicar(__IniProt + "71|"+pParametro + __FimProt)

Return ifRetorno

******************************************************************************
function if_Sang(ifVlr)
*********
* Efetua uma Sangria de Dinheiro no Caixa
*
* ifVlr=V(15,2)           -Valor da Sangria
*
*Pre-Requisitos
*
*Nao podera ter cupom fiscal aberto
*

   if ifVlr<=0
      Return '999999999'
   EndIF

   ifvlr=StrTran(StrTran(StrTran(StrZero(ifvlr,15,2),'.',''),',','') ,' ','')

   ifRetorno=ifcomunicar(__IniProt + "25|SA|"+ifvlr + __FimProt)

Return ifRetorno

******************************************************************************
function if_MemFiscal(ifDtIni,ifDtFim,ifSaida)
*********
* Emite Memoria Fiscal
*
* ifDtini=D(8)                     -Data Inicial
* ifDtfim=D(8)                     -Data Final
* ifSaida=D(8)                     -Saida
*
*Pre-requisitos
*
*O Cupom fiscal NAO devera estar aberto

   ifDtini=StrZero(Day(ifDtini),2,0)+StrZero(Month(ifDtini),2,0)+SubStr(StrZero(Year(ifDtini),4,0),3,2)
   ifDtfim=StrZero(Day(ifDtfim),2,0)+StrZero(Month(ifDtfim),2,0)+SubStr(StrZero(Year(ifDtfim),4,0),3,2)

   ifRetorno=ifcomunicar(__IniProt+'08|'+ifDtini+'|'+ifDtfim+'|I'+__FimProt)

Return ifRetorno
messenger : software_facil@hotmail.com
Voltar ao topo
Avatar do usuário
alaminojunior
Colaborador
Colaborador
Mensagens: 1717
Registrado em: 16 Dez 2005 21:26
Localização: Ubatuba - SP

Re: Abrir Cupom Fiscal - dúvidas

Mensagem por alaminojunior »

Me pareceu que você disponibiliza vários meios de se iniciar a venda e de finalizar também. Por isso, é essencial analizar os retornos, só eles vão dizer "em que pé a coisa está". Como eu já havia comentado, pode ser que você esteja enviando um comando sem que o anterior tenha tido êxito.
Compilador xHarbour 1.2.3 + Embarcadero C++ 7.30
MySQL c/ SQLRDD
HwGui + GTWVG
Voltar ao topo
Avatar do usuário
software_facil
Usuário Nível 3
Usuário Nível 3
Mensagens: 211
Registrado em: 23 Fev 2005 12:19
Localização: Curitiba/PR
Contato:
Contato software_facil

Re: Abrir Cupom Fiscal - dúvidas

Mensagem por software_facil »

Estou fazendo vários testes, até agora nada deu certo, mas acho que logo consigo, depois de tantas tentativas ! Se alguém tiver os comandos da MP-25 para : abrir cupom - vender normal - fechar cupom (só será usado dinheiro como forma de pagamento), ajudaria bastante.

Abraços

Marcelo Neves
messenger : software_facil@hotmail.com
Voltar ao topo
anacatacombs
Membro Master
Membro Master
Mensagens: 472
Registrado em: 12 Jul 2005 16:53
Localização: Cianorte-Paraná
Contato:
Contato anacatacombs

Re: Abrir Cupom Fiscal - dúvidas

Mensagem por anacatacombs »

Se tu quiser, posso mandar o manual no teu e-mail.

[]'s
Ana
Voltar ao topo
Avatar do usuário
software_facil
Usuário Nível 3
Usuário Nível 3
Mensagens: 211
Registrado em: 23 Fev 2005 12:19
Localização: Curitiba/PR
Contato:
Contato software_facil

Re: Abrir Cupom Fiscal - dúvidas *** RESOLVIDO ***

Mensagem por software_facil »

Obrigado aos amigos que responderam ao tópico. O problema foi solucionado, usando o manual da MP-20-FI, que contém exemplo de tudo em CLIPPER, o que ajudou muito, pois com o manual da MP-25-FI junto, pude ver o que estava faltando para fazer todo o processo correr normalmente.
Se tiver alguma área no fórum para disponibilizar o manual da MP-20-FI, por favor me avisem.

Abraços

Marcelo Neves
messenger : software_facil@hotmail.com
Voltar ao topo
Avatar do usuário
Pablo César
Usuário Nível 7
Usuário Nível 7
Mensagens: 5312
Registrado em: 31 Mai 2006 10:22
Localização: Curitiba - Paraná

Abrir Cupom Fiscal - dúvidas *** RESOLVIDO ***

Mensagem por Pablo César »

Se quiser Marcelo, pode postar aqui mesmo, como arquivo anexo em forma compactado para que os outros colegas possam aproveitar.

Moví este tópico, pois mesmo tendo ligação com a seção "Legislação Fiscal e Tributária", mais parece se adequar a "Contribuições, Dicas e Tutoriais".
Um clip-abraço !

Pablo César Arrascaeta
Compartilhe suas dúvidas e soluções com todos os colegas aqui do fórum.
Evite enviar as dúvidas técnicas por MPs ou eMails, assim todos iremos beneficiar-nos.
Voltar ao topo
Avatar do usuário
software_facil
Usuário Nível 3
Usuário Nível 3
Mensagens: 211
Registrado em: 23 Fev 2005 12:19
Localização: Curitiba/PR
Contato:
Contato software_facil

Re: Abrir Cupom Fiscal - dúvidas *** RESOLVIDO ***

Mensagem por software_facil »

Como o manual compactado, passa e muito dos 100kb suportados, acho melhor quem quiser, pedir por e-mail mesmo.

Abraços

Marcelo Neves
marcelo.souza.das.neves(at)gmail.com
messenger : software_facil@hotmail.com
Voltar ao topo
Avatar do usuário
sygecom
Administrador
Administrador
Mensagens: 7131
Registrado em: 21 Jul 2006 10:12
Localização: Alvorada-RS
Contato:
Contato sygecom

Re: Abrir Cupom Fiscal - dúvidas *** RESOLVIDO ***

Mensagem por sygecom »

Coloque no 4shared.com e post o link aqui.
Leonardo Machado
xHarbour.org + Hwgui + PostgreSql
Voltar ao topo
Responder

Voltar para “Contribuições, Dicas e Tutoriais”