Esconder campos digitados com asteriscos

[leafarfp]

Boa tarde , sou iniciante no clipper e preciso fazer um programa aki,
porem estou com um duvida e nao consigo sanar, eu quero que um determinado
campo ao digitar nele ao inves de aparecer o que foi digitado apareça
apenas asteriscos ou qualquer outra rachura que impeça de se ver o que foi
digitado. Isso e possivel. por exemplo em um campo caracteres com 5 espaços
iria digitar 12345 ao inves de aparecer os numeros apareça apenas os
asteriscos. vc poderia me ajudar. Segue abaixo o exempo de onde quero esconder os campos digiratos com asterisco

@ 8, 1 SAY "SOLICITANTE..:" GET M->SOLICITANT PICTURE "@!"

rfpacheco8@hotmail.com

[rbonotto]

Ta na mão: (rotina criada pelo Toledo)

Código: Selecionar todos

** Kiel - Ezequiel Moraes - ezequielmoraes@bol.com.br
** Exemplo para Pegar Senha e mostrar na tela *
** GETSEN(<senha>) - Retorna Senha se ENTER ou Vazio se ESC
** Clipper getsenha
** Rtlink ou Blinker

   CLS
   csenha := SPACE(10)
   calgo  := SPACE(10) 
   @01,00 SAY PADC("Kiel - Ezequiel Moraes - Exemplo para Pegar Senha",80)

   @05,37 Say "Digite Algo...: "  get calgo pict "@!" // apenas para mostrar 
                                                      // que este nao pega *

   @06,37 Say "Digite Senha..: " get csenha pict "@!"
   ATAIL(GETLIST):READER := {|BL1|GETSEN(BL1)}  // Pega csenha e 
                                                // mostra *

   @07,37 Say "Digite Algo...: "  get calgo pict "@!" // apenas para mostrar
                                                      // que este nao pega *
   READ

   @10,37 Say "Senha Digitada: "+csenha
   INKEY(0)
   CLS



PROCEDURE GETSEN(P1)

   LOCAL L2, L3, L4

   IF GETPREVALI(P1)

      P1:SETFOCUS()
      P1:CARGO := ""

      DO WHILE P1:EXITSTATE() == 0

         IF P1:TYPEOUT()

            P1:EXITSTATE := 5

         ENDIF

         DO WHILE P1:EXITSTATE() == 0

            L2 := INKEY(0)

            IF L2 >= 32 .AND. L2 <= 255

               P1:CARGO := P1:CARGO() + CHR(L2)
               GETAPPLYKE(P1, 42)

            ELSEIF L2 = 8

               P1:CARGO := SUBSTR(P1:CARGO(), 1, LEN(P1:CARGO()) - 1)
               GETAPPLYKE(P1, L2)

            ELSEIF L2 = 13  // Sai com tecla ENTER e retorna a
     		  	    // senha digitada
               GETAPPLYKE(P1, L2)

            ELSEIF L2 = 27  // Sai com Tecla ESC e retorna vazio

               GETAPPLYKE(P1, L2)

            ENDIF

         ENDDO

         IF  .NOT. GETPOSTVAL(P1)

            P1:EXITSTATE := 0

         ENDIF

      ENDDO

      P1:KILLFOCUS()

   ENDIF

   IF P1:EXITSTATE() <> 7

      P1:VARPUT(P1:CARGO())

   ENDIF

RETURN

Nota de Moderação:
por Pablo César: Foi reditada a mensagem, pois o código fonte postado não era o original e acusava a falta das funções: MSG(), CUR() e AVS() causando erro ao compilar.

[raquelreis]

Boa Tarde leafarfp,

Não sei substituir por asteriscos, mas uso COLOR "R/R" ai não mostra o q foi digitado.
Veja exemplo:

Código: Selecionar todos

cls
WHILE .T.
   IF LASTKEY() = 27
      CLS;EXIT
   ENDIF 

pSENHA := SPACE(05)

@ 11,39 SAY "SENHA" GET pSENHA PICT "@!" COLOR "R/R"
   READ

ENDDO 

[leafarfp]

Muito obrigado pessoal deu certo ) fiz do segundo modo, mas agradeço ambos pelas respostas rápidas

[Pablo César]

Disponibilizei um exemplo de cadastro, mudança e identificação com senhas scriptadas. A metodologia foram extraídas do Miro. E as senhas a medida que forem digitadas, aparecerão uns quadradinhos. Só para ampliar o grau do aprendizado, espero que gostem.

[Pablo César]

Tem mais outro exemplo que pode ser adaptado e que serviria para encriptar as senhas. Também é do PCToledo disponibilizado aqui no fórum em: da seção de Downloads, clique aqui para baixar

[rbonotto]

Ola leafarfp. Usuario não interage muito com caracteres que não aparecem. Digo isto pois utilizava assim e muitos clientes me reclamaram que o programa estava "congelado" pois digitavam e nada viam....usuários....rsrsrsrsrs

A funçao que disponibilizei é do Toledo ( é a mesmo que o pablo colocou o link ) e é bem mais agradavel ao usuario.

Abraços

[leafarfp]

Amigo vou ser sincero eu tb axo sua maneira melhor porém nao sei como aplicar o programa e quase todo gerado pelo miro e sou muito fraco em programação só o básico se vc puder me ajudar mando o fonte pra vc

[rbonotto]

Ola leafarfp, mande os fontes que tentarei te ajudar:

xxxxxxx@xxxxxxxxxx

Abraços,

Nota de Moderação:
por [url=https://pctoledo.org/forum/memberlist.php?mode=viewprofile&u=100899][color=#00AA00]Pablo César[/color][/url]: (de acordo a sua ultima citação) 
 
Enviar por email, resolver através de meios privados são práticas não aceitas aqui no fórum. Desestimulamos este tipo de procedimento, já que o objetivo do fórum é para servir como fonte centralizadora de informações, onde os usuários possam compartilhar de forma pública e não exclusiva. Favor ler a Regra Geral do Fórum (itens 10,11,12 e 13).