Dúvida sobre o controle Texbox

[Paulo_CPV]

Bom dia! A todos do grupo,

Estou uqerendo tirar a borda do comando Textbox para ficar no estilo do Clipper, mas não estou conseguindo, será que alguém do grupo pode me ajudar? Estou fazendo da seguinte forma:

Código: Selecionar todos

Define Textbox text_1



NOBORDER .t. <- Aqui dá erro de sintaxe

End Textbox

[]'s
Paulo Jacareí/SP

[Mario Mesquita]

Olá.

É HMG mesmo?

Pela IDE não tem essa propriedade NoBorder...

[Pablo César]

Oi Paulo, eu nunca vi esse NoBorder. Ai pesquisando vi que para Minigui Extended e para HMG só tem para:

- @ ... PRINT RECTANGLE (C:\MiniGUI\SAMPLES\BASIC\miniprint\demo.prg)
- DRAW GRAPH (C:\MiniGUI\SAMPLES\BASIC\Histogram\demo.prg e C:\hmg.3.1.4\SAMPLES\Controls\Graph\GRAPH.03\demo.prg)
- @ ... ANIMATEBOX (C:\MiniGUI\SAMPLES\BASIC\ANIMATEDEMO\demo.prg)

Mas para TextBox, agora vi que a instrução é para apenas colocar NOBORDER (sem o .T.) em Minigui Extended e em HMG não existe isso.

[Paulo_CPV]

Bom dia! Colhas do grupo,

A cláusula realmente faz parte da Minigui Extend na versão 223b. A mesma NOBORDER está citada na documentação da Minigui na pasta C:|Minigui\Doc, arquivo Minigui.chm na opção Controls Command e Textbox.

[]'s
Paulo - Jacareí/SP

[Paulao]

Boa tarde aos amigos do forum, alquem conseguiu resolver o problema do noborder com o controle textbox, uso a minigui extended e enfrento o mesmo problema, no help do controle aparece a opcao noborder, mas da erro qdo gero o sistema, e eu coloco simplesmente NOBORDER retorna o erro Error E0020 Incomplete statement or unbalanced delimiters, Se coloco NOBORDER .T. retorna o erro Error E0030 Syntax error "syntax error at '.T.'".

Grande abraço

[Toledo]

Paulao, realmente o TEXTBOX está com problema no NOBORDER quando se usa a sintaxe DEFINE TEXTBOX.... END TEXTBOX. Mas se você usar @ nRow, nCol TEXTBOX, o NOBORDER funciona corretamente.

Código: Selecionar todos

#include "minigui.ch"

Function Main

	SET NAVIGATION EXTENDED

	DEFINE WINDOW Form_1 ;
		AT 0,0 ;
		WIDTH 640 HEIGHT 480 ;
		TITLE 'NOBORDER Demo' ;
		MAIN ;
		ON INIT Form_1.Text_1.SetFocus

		@ 10,10 TEXTBOX Text_1 ;
			VALUE 11 ;
			NUMERIC

		@ 40,10 TEXTBOX Text_2nb ;
			VALUE 11 ;
			NUMERIC ;
			NOBORDER

	END WINDOW

	Form_1.Center
	Form_1.Activate

Return Nil

Bom, para usar NOBORDER na sintaxe DEFINE TEXTBOX... END TEXTBOX, ai você vai ter que corrigir o arquivo i_altsyntax.ch que está nas pasta \INCLUDE da MiniGui, para isto siga as instruções abaixo:

1 - EDITAR o arquivo i_altsyntax.ch e procurar por:

Código: Selecionar todos

#xcommand END TEXTBOX;

2 - Uma linha antes do comando acima, incluir o código abaixo:

Código: Selecionar todos

#xcommand NOBORDER <noborder>;
   =>;
   _HMG_ActiveControlBorder      := !<noborder>

3 - Salvar o arquivo i_altsyntax.ch.

Agora o NOBORDER vai funcionar nas duas sintaxes, veja um exemplo:

Código: Selecionar todos

#include "minigui.ch"

Function Main

	SET NAVIGATION EXTENDED

	DEFINE WINDOW Form_1 ;
		AT 0,0 ;
		WIDTH 640 HEIGHT 480 ;
		TITLE 'NOBORDER Demo' ;
		MAIN ;
		ON INIT Form_1.Text_1.SetFocus

		DEFINE textbox Text_1
			Row 10
			Col 10
			value 11
			NUMERIC .T.
		END textbox

		@ 40,10 TEXTBOX Text_2 ;
			VALUE 11 ;
			NUMERIC

		DEFINE textbox Text_1nb
			Row 10
			Col 150
			value 11
			NUMERIC .T.
			NOBORDER .T.
		END textbox

		@ 40,150 TEXTBOX Text_2nb ;
			VALUE 11 ;
			NUMERIC ;
			NOBORDER

	END WINDOW

	Form_1.Center
	Form_1.Activate

Return Nil

Abraços,

[microvolution]

boa noite!
alguém sabe se o Dr. Soto, ou o outro mantenedor da HMG (Mnigui ROberto Lopez) acrescentou o NOBORDER no TEXTBOX?

[Claudio Soto]

boa noite!
alguém sabe se o Dr. Soto, ou o outro mantenedor da HMG (Mnigui ROberto Lopez) acrescentou o NOBORDER no TEXTBOX?

No recuerdo bien, pero me parece que no esta implementando en HMG oficial.

[microvolution]

no esta implementando

"gracias y gracias" y buen fin de semana