Abrir Word com Hmg

[Rm.Software]

Oi Pessoal saudações Clippertorianas :{

Estou utilizando o Hmg 3.2 para fazer meu trabalho e gostaria que alguem se possivel desse uma ajuda.

Eu monto um DBF com todos os dados que preciso EX. Nome, Idade, estado civil, etc
E Tenho varios arquivos no Word para determinados problemas que interpretam estes dados e montam o documento.
Abro o documento pelo Word o mesmo reconhece o dbf, interpreta os dados e monta o documento sem problema.
Ate ai esta otimo não preciso de nada. )

O problema veem agora :'(

Eu resolvi usar o programa para abrir o documento direto, Ele abre o diretorio, eu escolho o documento, ele abre o documento no Word.

Código: Selecionar todos

  x := Getfile ( { {'All Files','*.Doc'} } , 'Abrir Arquivos' , 'C:\ADMI2\DOC\'+RTRIM(LEFT(cUsuario,8))+'\' , .F. , .T. )
  IF !Empty(x)
     MsWord( x )	
  ENDIF

PROCEDURE MsWord( x )
 LOCAL oWord

   oWord := CreateObject( "Word.Application" )
   
   oWord:Visible := .T.
   oWord:WindowState := 1 
   oWord:Documents:Open( x )	
   
RETURN

Mas não consigo fazer ele encontrar o dbf para interpretar os campos. Alguém pode me dar uma dica

ja tentei usar assim

* pega a fonte de dados : MontaEdt.dbf
oWord:MailMerge:OpenDataSource('C:\ADMI2\DOC\'+RTRIM(LEFT(cUsuario,8))+'\'+'MontaEdt.DBF')
LinkToSource:= .T.
Connection:="TABLE MontaEdt"
SQLStatement:= "Select * from [ 'C:\ADMI2\DOC\'+RTRIM(LEFT(cUsuario,8))+'\'+'MontaEdt.DBF' ]"

* Executa a mala direta
oWord:MailMerge:Execute

e nada feito

[Rm.Software]

Oi Pessoal

O engraçado é se eu clicar com o botão direito do mouse sobre o documento ele abre normalmente. Ate mostrar a mensagem
Se alguem puder dar uma mão desde ja agradeço.

[Toledo]

Amigo, faz um teste com este exemplo:

Código: Selecionar todos

#include "minigui.ch"

Func Main()
Local cUsuario:="Toledo"
Private cPasta:="C:\ADMI2\DOC\"+RTRIM(LEFT(cUsuario,8))+"\"

   DEFINE WINDOW Form_1 ;
      AT 0,0 ;
      WIDTH 400 HEIGHT 300 ;
      TITLE 'Exemplo Abrir DOC Word - Mala Direta' ;
      MAIN

	@ 10,10 BUTTONEX BUTTON_1 ;
			CAPTION "Abrir DOC" ;
			ACTION {|| Abre() } ;
			WIDTH 120 ;
			HEIGHT 60

   END WINDOW

   Form_1.Center
   Form_1.Activate

Return Nil

Func Abre()
Local x := Getfile ( { {'All Files','*.Doc'} } , 'Abrir Arquivos' , cPasta , .F. , .T. )

  IF !Empty(x)
     MsWord( x )   
  ENDIF

Return Nil

PROCEDURE MsWord( x )
LOCAL oWord, oDoc

   oWord := CreateObject( "Word.Application" )
   
   oDoc := oWord:Documents:Open( x )
   oDoc:MailMerge:OpenDataSource(cPasta+"MontaEdt.DBF")
   oDoc:MailMerge:ViewMailMergeFieldCodes := .F.
   oWord:WindowState := 1 
   oWord:Visible := .T.
   
RETURN

Abraços,

[Rm.Software]

Nossa muito obrigado!

Serviu perfeitamente, nada melhor do que perguntar pra quem realmente entende.

Agora só me resta fazer abrir os arquivos com extensão xls e pdf

mais uma vez muito obrigado