Error TOLEAUTO/-1 Unknown Error: TOLEAUTO:NEW

Mensagem por **Kapiaba** » 17 Mar 2015 11:29

   Descricao do Erro: ERROR TOLEAUTO/-1  UNKNOWN ERROR: TOLEAUTO:NEW
   Argumentos:
     [   1] = C   InternetExplorer.Application

Lista dos Erros
===============
   Erro em:  => THROW(0)
   Erro em: win32ole.prg => TOLEAUTO:NEW(309)
   Erro em: win32ole.prg => CREATEOBJECT(67)
   Erro em: DBMANUT2.prg => NFE_CHECAPORTAL(977)

Linha 977 quebra quando eu clicko pela segunda vez para entrar no portal???

Código: Selecionar todos

 oOle:= CreateObject("InternetExplorer.Application")  // quebra aqui

Codigo usado:

Código: Selecionar todos

FUNCTION NFe_ChecaPortal( f_cChave, f_nPortal )

   LOCAL oOle, oOleDoc := Array(2)

   Default f_nPortal := 1, f_cChave := ""

   HB_GCALL( .F. )

   oOle:= CreateObject("InternetExplorer.Application")  // quebra aqui
   oOle:Visible   := .T. // Apresenta o Browser
   oOle:ToolBar   := .F. // Desativa a barra de ferramentas
   oOle:StatusBar := .F. // Desativa a barra de status
   oOle:MenuBar   := .F. // desativa a barra de menu

   If f_nPortal == 1

      oOle:Navigate2("http://www.nfe.fazenda.gov.br/portal/consulta.aspx?tipoConsulta=completa&tipoConteudo=XbSeqxE8pl8=")

   Else  // Portal Estadual

      oOle:Navigate("http://nfe.fazenda.sp.gov.br/ConsultaNFe/consulta/publica/ConsultarNFe.aspx") // Abre o site

   EndIf

   // Maximiza o Internet explorer
   hWnd:=oOle:hWnd

   //ShowWindow(hWnd, 3 )         //SW_MAXIMIZE=3 SW_NORMAL=1 SW_MINIMIZE=6
   ShowWindow(hWnd, 1 )         //SW_MAXIMIZE=3 SW_NORMAL=1 SW_MINIMIZE=6

   BringWindowToTop(hWnd)

   WHILE oOle:Busy

      SysWait(.5)

   END

   If f_nPortal == 1  // Portal Nacional

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentPlaceHolder1$txtChaveAcessoCompleta",0):Value := f_cChave

   Else  // portal de Sao Paulo

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentMain$tbxIdNFe"):Value := f_cChave

   EndIf

   SysRefresh()

   oOle:Close()

return( .T. )

Obg. abs.

Mensagem por **Kapiaba** » 17 Mar 2015 15:34

Resolvido desta forma:

Código: Selecionar todos

FUNCTION NFe_ChecaPortal( f_cChave, f_nPortal )  // VEM DE DBMANUT.PRG

   LOCAL oOle, oOleDoc := Array(2)

   Default f_nPortal := 1, f_cChave := ""

   HB_GCALL( .F. )

   TRY

      oOLE := GetActiveObject( "InternetExplorer.Application" )

   CATCH

      TRY
         oOLE := CreateObject( "InternetExplorer.Application" )

      CATCH

         MsgInfo( "ERRO no Internet Explorer", "Erro no IE" )

         RETURN NIL

      END

   END

   oOLE:Visible   := .F.
   oOle:ToolBar   := .F. // Desativa a barra de ferramentas
   oOle:StatusBar := .F. // Desativa a barra de status
   oOle:MenuBar   := .F. // desativa a barra de menu

   If f_nPortal == 1  // Portal do Governo Federal

      oOle:Navigate2("http://www.nfe.fazenda.gov.br/portal/consulta.aspx?tipoConsulta=completa&tipoConteudo=XbSeqxE8pl8=")

   Else  // Portal do Estado de Sao Paulo

      oOle:Navigate("http://nfe.fazenda.sp.gov.br/ConsultaNFe/consulta/publica/ConsultarNFe.aspx") // Abre o site

   EndIf

   // Maximiza o Internet explorer
   hWnd := oOle:hWnd

   ShowWindow( hWnd, 1 )  // SW_MAXIMIZE=3 SW_NORMAL=1 SW_MINIMIZE=6

   BringWindowToTop(hWnd)

   WHILE oOLE:Busy

      HB_IDLESLEEP( .5 )

   ENDDO

   If f_nPortal == 1  // Portal Nacional

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentPlaceHolder1$txtChaveAcessoCompleta",0):Value := f_cChave

   Else  // portal de Sao Paulo

      oOle := oOle:Document()
      oOle:All:Item("ctl00$ContentMain$tbxIdNFe"):Value := f_cChave

   EndIf

   SysRefresh()

   //oOle:Quit()
   oOle := Nil

RETURN NIL

Obg. abs.