Hwgui saiu da casca, veja os códigos.

[Itamar M. Lins Jr.]

Olá!
Os controles fora do padrão windows.
DRAW CHECK, DRAW EDIT e EDIT DATE, DRAW OSAY, DRAW RADIO...

Código: Selecionar todos

// Board and drawn items
#include "hwgui.ch"

#define CLR_WHITE    0xffffff
#define CLR_BLACK    0x000000
#define CLR_DGRAY2   0x555555
#define CLR_DGRAY3   0x888888

FUNCTION Test
   LOCAL oDlg, oBoard, oTrack, oSay, oFont := HFont():Add( "MS Sans Serif", 0, - 13 )
   LOCAL aCorners := { 4,4,4,4 }
   LOCAL aStyles := { HStyle():New( { CLR_DGRAY2 }, 1, aCorners ), ;
      HStyle():New( { CLR_WHITE }, 2, aCorners ), ;
      HStyle():New( { CLR_DGRAY3 }, 1, aCorners ) }
   LOCAL bChange := {|o|
      oSay:SetText( LTrim(Str(o:value)) )
      RETURN .T.
   }

   INIT DIALOG oDlg TITLE "Board and drawn items"  ;
      AT 210, 10  SIZE 440, 220 FONT oFont BACKCOLOR CLR_DGRAY2

   @ 4, 4 BOARD oBoard SIZE 432, 212 BACKCOLOR CLR_BLACK ;
      ON PAINT {|o,h|FPaint(o,h)} ON SIZE {|o,x,y|o:Move(,,x-8,y-8)} KEYBOARD

   @ 12, 12 DRAWN RADIO OF oBoard GROUP "m" SIZE 20, 30 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      HSTYLES aStyles TEXT 'X' FONT oFont INIT .T.
   @ 12, 56 DRAWN RADIO OF oBoard GROUP "m" SIZE 20, 30 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      HSTYLES aStyles TEXT 'X' FONT oFont

   @ 36, 12 DRAWN OF oBoard SIZE 90, 30 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      TEXT 'Radio 1' FONT oFont
   @ 36, 56 DRAWN OF oBoard SIZE 90, 30 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      TEXT 'Radio 2' FONT oFont

   @ 140, 12 DRAWN CHECK OF oBoard SIZE 20, 30 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      HSTYLES aStyles TEXT 'X' FONT oFont
   @ 140, 56 DRAWN CHECK OF oBoard SIZE 20, 30 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      HSTYLES aStyles TEXT 'X' FONT oFont

   @ 164, 12 DRAWN OF oBoard SIZE 90, 30 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      TEXT 'Check 1' FONT oFont
   @ 164, 56 DRAWN OF oBoard SIZE 90, 30 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      TEXT 'Check 2' FONT oFont

   @ 280, 12 DRAWN EDIT Date() OF oBoard SIZE 80, 28 COLOR CLR_BLACK BACKCOLOR CLR_WHITE
   @ 280, 56 DRAWN EDIT "Sample Drawn Edit Control" OF oBoard SIZE 140, 28 COLOR CLR_BLACK BACKCOLOR CLR_WHITE

   @ 80, 140 DRAWN oSay OF oBoard SIZE 100, 30 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      TEXT '0.00' FONT oFont

   @ 40, 168 DRAWN TRACK oTrack OF oBoard SIZE 180, 18 COLOR CLR_WHITE BACKCOLOR CLR_BLACK ;
      SLIDER SIZE 28 SLIDER HSTYLE HStyle():New( { 0x888888, 0xcccccc }, 3 ) AXIS
   oTrack:bChange := bChange

   ACTIVATE DIALOG oDlg
   oFont:Release()

   RETURN Nil

STATIC FUNCTION FPaint( o, hDC )

   hwg_Fillrect( hDC, 0, 0, o:nWidth, o:nHeight, o:brush:handle )

   RETURN Nil

Captura de tela 2023-08-18 214116.png (4.2 KiB) Exibido 942 vezes

Saudações,
Itamar M. Lins Jr.

[JoséQuintas]

Preciso ver os fontes, se o exemplo usa um único HBOARD, ou se é exemplo de HBOARD dentro de HBOARD.

Dependendo disso, pode ser um mal negócio, poderia ser transformar a hwgui no que nem uso da GTWVG, que por sua vez, é o que você detesta da GTWVG.
Espero que seja a segunda situação.

[Itamar M. Lins Jr.]

Olá!

que por sua vez, é o que você detesta da GTWVG.

Não tem nada a ver. Não detesto coisa alguma nesse sentido. Nunca disse que detestava nada de programação...
Digo que está ultrapassado! É bem diferente! Uso de savescreen etc... pouco ou zero controle sobre os objetos desenhados... que nem desenhados são. São todos padrões antigos do DOS...Enfim aqui é (forum)área da Hwgui GT só se for o da Hwgui! Que também temos.
Detestar envolve outros fatores, que não tem a ver com forum técnico.
E esses novos leiautes podemos dizer SHAPE da Hwgui não desfez o uso da forma padrão.
Eu compilo aqui meu ERP e testo e vejo os BUGs que podem ocorrer e reporto para ele.
São poucos os controles que eu não faço uso da Hwgui.

Saudações,
Itamar M. Lins Jr.

[JoséQuintas]

Não tem nada a ver. Não detesto coisa alguma nesse sentido. Nunca disse que detestava nada de programação...
Digo que está ultrapassado! É bem diferente! Uso de savescreen etc... pouco ou zero controle sobre os objetos desenhados... que nem desenhados são. São todos padrões antigos do DOS...Enfim aqui é (forum)área da Hwgui GT só se for o da Hwgui! Que também temos.
Detestar envolve outros fatores, que não tem a ver com forum técnico.
E esses novos leiautes podemos dizer SHAPE da Hwgui não desfez o uso da forma padrão.
Eu compilo aqui meu ERP e testo e vejo os BUGs que podem ocorrer e reporto para ele.
São poucos os controles que eu não faço uso da Hwgui.

Pois é....
Fazer o que...
Baseado no texto, hwgui agora também é DOS.
Só falta save screen/restore screen.